Проблема использования с Find ADODB.Recordset

[anvg]

Создаю ADODB.Recordset (Microsoft ActivX Data Objects 2.5 Library) в Excel 2010

Код: Выделить всё

    Dim pTable As New ADODB.Recordset
    pTable.Fields.Append "FLength", adDouble
    pTable.CursorLocation = adUseClient
    pTable.Open
   
    pTable.AddNew: pTable(0).Value = 715
    pTable.AddNew: pTable(0).Value = 916
    pTable.AddNew: pTable(0).Value = 830


Пытаюсь найти требуемое число по критерию методом Find

Код: Выделить всё

    pTable.Sort = "FLength DESC"
    pTable.MoveFirst
    pTable.Find "FLength<=" & CStr(730), SearchDirection:=adSearchForward
    Debug.Print pTable(0).Value
    pTable.Close


Получаю 916. Что делаю не так? И как правильно? Или остаётся только работать через Filter?

[alibek]

Полный текст ошибки и строку, на которой происходит ошибка, укажи. И тип курсора укажи.

[anvg]

А я разве писал, что получаю исключение (ошибку)? Ошибка в результате в Immediate выводиться 916 (легко проверить, заключив весь код в Sub Test() ... End Sub), а должно быть 715. Тип курсора adOpenStatic = 3.
На www.sql.ru подсказали, что это старый "глюк" присутствующий и в библиотеке 2.8. При сортировке по возрастанию и поиску с конца, вроде, работает нормально, но ведь может быть и более сложная сортировка.

[Sam777e]

pTable.Fields.Append "FLength", adDouble

Здесь система "знает", что тип Double

pTable.AddNew: pTable(0).Value = 715

pTable.Find "FLength<=" & CStr(730)

А здесь ей откуда знать - для нее строка поиска ПРОСТО ТЕКСТ.
Вероятно, в поиске будет "pTable.Find "FLength<=730", а надо, скорее, "FLength<=730.000Х" ( Х - это знак типа, я не помню какой для Double, # что-ли ). Короче, трудности со сравнением в нецелой ситуации. И я бы пробовал pTable.Find . . . Cstr(Cdbl(730))

[Qwertiy]

А здесь ей откуда знать - для нее строка поиска ПРОСТО ТЕКСТ.

Возможно, я чего-то не понимаю, но как в данной ситуации это может повлиять на результат? Есть несколько положительных чисел одного порядка. Для них лексикографическое сравнение даёт тот же результат, что и числовое.

Cstr(Cdbl(730))

Насколько я помню, VB в любом случае нули отрежет...

[anvg]

Sam777e
Это просто "глюк". При сортировке по убыванию находит не правильно. Продемонстрирую на коде. По смыслу одинаково, а результат разный.

Код: Выделить всё

Public Sub testDESC()
    Dim pTable As New ADODB.Recordset
    pTable.Fields.Append "FLength", adDouble
    pTable.CursorLocation = adUseClient
    pTable.Open
   
    pTable.AddNew: pTable(0).Value = 715#
    pTable.AddNew: pTable(0).Value = 916#
    pTable.AddNew: pTable(0).Value = 830#
   
    pTable.Sort = "FLength DESC"
    pTable.Find "FLength<=730.0", SearchDirection:=adSearchForward, Start:=adBookmarkFirst
    Debug.Print pTable(0).Value
    pTable.Close
End Sub


Получим 916 вне зависимости от формы записи числа (лишь бы разделитель точка)
А при сортировке по возрастанию правильно.

Код: Выделить всё

Public Sub testASC()
    Dim pTable As New ADODB.Recordset
    pTable.Fields.Append "FLength", adDouble
    pTable.CursorLocation = adUseClient
    pTable.Open
   
    pTable.AddNew: pTable(0).Value = 715#
    pTable.AddNew: pTable(0).Value = 916#
    pTable.AddNew: pTable(0).Value = 830#
   
    pTable.Sort = "FLength"
    pTable.Find "FLength<=730.0", SearchDirection:=adSearchBackward, Start:=adBookmarkLast
    Debug.Print pTable(0).Value
    pTable.Close
End Sub


Как и должно быть 715.

[alibek]

А при сортировке по возрастанию правильно.

Видимо действительно баг.
Полная версия ADODB какая? Сервис-паки установлены?

[anvg]

Создаю ADODB.Recordset (Microsoft ActivX Data Objects 2.5 Library)

Пробовал с версиями 2.0, 2.1, 2.8.
Excel 2010 32bit, Windows 7 64bit. Сервис-паки и обновления установлены. В конторе организовано автоматическое обновление. Софт лицензионный.

[Sam777e]

Я понимаю, что предлагаю не вариант - панацею, но . . .

.Find S, SearchDirection:=adSearchBackward, Start:=adBookmarkLast

Код: Выделить всё

Public Sub testDESC_2()
  Dim pTable As New ADODB.Recordset
  Dim j As Long, S As String
 
  pTable.Fields.Append "FLength", adDouble
  pTable.CursorLocation = adUseClient
  pTable.Open
 
  pTable.AddNew: pTable(0).Value = 715#
  pTable.AddNew: pTable(0).Value = 916#
  pTable.AddNew: pTable(0).Value = 728#
  pTable.AddNew: pTable(0).Value = 830#
 
  With pTable
    Debug.Print vbNewLine; " Sozdali"
    j = 1
    .MoveFirst
    Do
      If .EOF Then Exit Do
     
      Debug.Print j, pTable.Fields(0).Value
      .MoveNext: j = j + 1
    Loop
   
    .Sort = "FLength DESC"  ' <<===========
   
    Debug.Print vbNewLine; " Otsortirovali po UBYVANIJU"
    j = 1
    .MoveFirst
    Do
      If .EOF Then Exit Do
     
      Debug.Print j, pTable.Fields(0).Value
      .MoveNext: j = j + 1
    Loop
   
    Debug.Print vbNewLine; " Poisk"
   
    S = "FLength<=730.0"
    .Find S, SearchDirection:=adSearchBackward, Start:=adBookmarkLast
    Debug.Print S; pTable(0).Value
   
    S = "FLength>730.0"
    .Find S, SearchDirection:=adSearchBackward, Start:=adBookmarkLast
    Debug.Print S; pTable(0).Value
   
    S = "FLength>720.0"
    .Find S, SearchDirection:=adSearchBackward, Start:=adBookmarkLast
    Debug.Print S; pTable(0).Value
   
    S = "FLength>830.0"
    .Find S, SearchDirection:=adSearchBackward, Start:=adBookmarkLast
    Debug.Print S; pTable(0).Value
  End With
   
  pTable.Close
End Sub


Результат :
Sozdali
1 715
2 916
3 728
4 830

Otsortirovali po UBYVANIJU
1 916
2 830
3 728
4 715

Poisk
FLength<=730.0 715
FLength>730.0 830
FLength>720.0 728
FLength>830.0 916

[Qwertiy]

FLength<=730.0 715

Мне кажется, или правильно было бы 728?

[Sam777e]

FLength<=730.0 715

Мне кажется, или правильно было бы 728?

До некоторой степени согласен; особенно, если смотреть с формальной точки зрения. Но тогда надо и задачу ставить формально: есть записи, отсортированные по убыванию. Надо найти 1-ую СВЕРХУ... <=730.0 . Find НЕ работает корректно. Обязательно ли пользоваться фильтром или есть другие варианты?

Некий ответ:
1. ищем СНИЗУ > 730.0 [ как в моем предыдущем посте ]
2. нашли - [ по возможности, т.е., с проверками и.т.п. ] MoveNext
3. сумели сдвинуться - это и есть нужная запись

[Qwertiy]

Если можно получить доступ к записи в отсортированном списке по индексу, то это надо использовать в своём бинарном поиске.

[anvg]

Спасибо всем за обсуждение

[alibek]

Пробовал с версиями 2.0, 2.1, 2.8.

Я имел ввиду полный номер версии.
Последней версией для XP должна быть 2.81.1132.0.
Если установленная версия младше, возможно в последующих обновлениях MDAC этот баг устранен.