Помогите организовать цикл

[Вячеслав]

Помогите организовать цикл есть лист с числами
88656
56623
85612
75395
и тд.
Нужно пройти по ячейкам сверху в низ и найти скажем число 56623.
Спасибо.

[Viper]

Зачем цикл то? Есть метод Find для Range. Ежели таки надо циклом искать, то в каком месте затруднение то? Подробности в виде не получившегося или нефурычащего кода в студию!

[Вячеслав]

Ок ок.
сочинил такой код
Dim S, A, E, T As Variant
Dim i, X, Y As Integer


Windows("Основные_1c_8m.xlsm").Activate

A = ActiveCell.Value

Windows("Обор_43.xls").Activate

Cells.Find(What:=A, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False, SearchFormat:=False).Activate

S = ActiveCell.Offset(rowoffset:=0, Columnoffset:=3).Value

Windows("Основные_1c_8m.xlsm").Activate

ActiveCell.Offset(rowoffset:=0, Columnoffset:=15).Value = S
Все отлично если есть такая запись, а если нет получаем ошибку.
Подскажите как обработать.

[Genyaa]

Есть такая конструкция

On Error GoTo метка
или
On Error Resume Next

Почитайте справку по ней и используйте.

[Pavel55]

Правильная обработка поиска значений на листе

Код: Выделить всё

Sub Test()
Dim FoundRng As Range
Dim SoughtStr As String

    SoughtStr = "Test" 'ищем слово "Test" на листе "Лист1"
    Set FoundRng = Worksheets("Лист1").Cells.Find(What:=SoughtStr)

    If Not FoundRng Is Nothing Then
        MsgBox "Строка """ & SoughtStr & """ найдена в ячейке " & FoundRng.Address
    Else
        MsgBox "Строка """ & SoughtStr & """ не найдена на листе!"
    End If

    Set FoundRng = Nothing

End Sub

Поэтому введите объектную переменную типа Range, например,

Код: Выделить всё

Dim iRange as Range

присваивайте ей значения поиска (только слово .Activate в конце уберите)

Код: Выделить всё

Set iRange = Cells.Find(What:=A, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False, SearchFormat:=False)

и проверяйте его на Nothing - если переменная равно Nothing - ничего не найдено, если Not is Nothing - найдено! Адрес ячейки будет

Код: Выделить всё

Adr = iRange.Address

P.S. Вы неправильно объявляете переменные

Dim a, b, c As Ingeter - тут только "c" будет Ingeter, а "a" и "b" будут Variant. Поэтому надо

Код: Выделить всё

Dim a As Integer, b As Integer, c As Integer

либо тоже самое, но короче

Код: Выделить всё

Dim a%, b%, c%

% - Integer
& - Long
! - Single
# - Double
@ - Currency
$ - String

P.P.S. Слова rowoffset:= и Columnoffset:= можете не писать, пишите просто

Код: Выделить всё

ActiveCell.Offcet(0,15) = S