Как получить диапазон ячеек с .Value Like Mask & "*

[Чудовище под кроватью]

Хочу просто получить диапазон ячеек листа, подходящих под текстовый шаблон. Без всяких циклов. Методом Find, SpecialCells или чем-то подобным.

[KL]

Не уверен, что такое возможно. Самое быстрое, что мне приходит в голову это след. код (приблизительно то же делает кнопка "найти все" в диалоге "поиск")

Код: Выделить всё

Option Explicit
Sub Test()
    Dim rng As Range, c As Range, cnt As Long
    Dim i As Long, msk As String, res As Range
    msk = "Я идиот! Убейте меня, кто-нибудь!???PhotoSmart*"
    On Error Resume Next
    Set rng = ActiveSheet.UsedRange
    Set c = rng.Find(msk, rng(1), , xlWhole)
    cnt = Application.CountIf(rng, msk)
    For i = 1 To cnt
        If res Is Nothing Then Set res = c Else Set res = Union(res, c)
        Set c = rng.Find(msk, c, , xlWhole)
    Next i
    res.Select
End Sub

[Чудовище под кроватью]

Не уверен, что такое возможно. Самое быстрое, что мне приходит в голову это след. код (приблизительно то же делает кнопка "найти все" в диалоге "поиск")

Я быстрее как-нибудь хочу - чтобы без цикла. Вызвал метод - получил Range объект. Но countif тоже хорошо придумано.
В моем случае надо искать не во всех ячейках, а только в определенном столбце и шаблон начинается известным текстом (т.е. параметром, но это не важно).
Вот, думаю, сортировку сделать, чтобы они в кучу встали. Тогда нужный мне диапазон будет: Range().Find.Resize(CountIf). - Без цикла, что неплохо,... НО работает только с вызовом сортировки и только если шаблон не начинается с "*"

[KL]

Я быстрее как-нибудь хочу - чтобы без цикла. Вызвал метод - получил Range объект.

Да-ааааа? Ну тогда сразу отбрасывай Find и SpecialCells (последний просто не ищет по маскам, а лишь по индексированным ячейкам)

[Чудовище под кроватью]

KL
А AdvancedFilter?

[KL]

Это первое что пришло мне в голову после твоего ответа
Думаю, без цикла не обойдется, т.к. придется фильтровать столбец за столбцем во избежание конфликтов в строках. Правда цикл будет ограничен 256 пассами, но все равно придется использовать медлительную функцию Union (правда всего 255 раз) и ограниченный 8.192 несмежными областями метод SpecialCells(xlCellTypeVisible). На мой вкус могло бы получиться довольно сносно, но опять же от цикла не убежишь.

[KL]

Чудовище под кроватью,

Ты напрасно дописываешь в сообщения после того, как я на них ответил я уже дважды чудом наскакивал на твои дополнения. Получается что некоторые мои ответы какбы невпопад

В моем случае надо искать не во всех ячейках, а только в определенном столбце и шаблон начинается известным текстом (т.е. параметром, но это не важно).

в таком сл. AdvancedFilter - это то, что надо (см. приложение)

вот сам код:

Код: Выделить всё

Sub Macro1()
    Dim strMsk As String, rng As Range, rngCrit As Range
   
    On Error Resume Next
    strMask = InputBox("Insert a mask", "Select by mask", "'=TEST*")
    Set rngCrit = Sheets("Sheet2").Range("A1:A2")
    Set rng = Sheets("Sheet1").[C:C]
    rngCrit(1) = rng(1)
    rngCrit(2) = strMask
   
    rng.AdvancedFilter xlFilterInPlace, rngCrit
    rng.Resize(rng.Count - 1).Offset(1).SpecialCells(xlCellTypeConstants).SpecialCells(xlCellTypeVisible).Select
    rng.Parent.ShowAllData
End Sub

Но помни о 8.192 несмежных областях - Excel подло промолчит в случае ошибки

[Чудовище под кроватью]

KL
Большое спасибо!