Ошибка PasteSpecial

[Andrey_K]

Приветствую.
Столкнулся с проблемой. Надо скопировать некий диапазон с одного листа и вставить в новую книгу. Но при соблюдении всего (т.е. ширина столбцов, строк, формата ячеек, и соответственно данных)
Решение задачи "в лоб" не проходит, т.е. запускаю в екселе создать макрос, проделываю все операции с помощью специальной вставки, закрываю макрос. Проверяю его работу и сталкиваюсь с ошибкой "1004 метод PasteSpecial из класса Range завершен неверно"
Как такое может быть, ексел не может выполнить то что сам записал и сделал 10 секунд назад.

Кусочек кода привожу:
Sub makro3()
Range("A678:R679").Select
Selection.Copy
Workbooks.Add
Selection.PasteSpecial Paste:=xlColumnWidths, Operation:=xlNone, _
SkipBlanks:=False, Transpose:=False
Range("A1").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
End Sub

Подскажите в чем ошибка? (офис2000)

ЗЫ Копирование всего листа и удаление ненужного очень долго и "геморойно".

[SoulDevil]

Sub makro3()
Range("A678:R679").Select
Selection.Copy
Workbooks.Add
Selection.PasteSpecial Paste:=xlColumnWidths, Operation:=xlNone, _
SkipBlanks:=False, Transpose:=False
Range("A1").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
End Sub

Я бы делал так...

Sub makro3()
Range("A678:R679").Copy
Workbooks.Add
Range("A1").Select
Selection.PasteSpecial Paste:=xlPasteColumnWidths
Selection.PasteSpecial Paste:=xlPasteFormats
Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats
End Sub

Поменять высоту строк через вставку нельзя или я не знаю как... Я бы их "прочитал", сохранил в массив и назначил отдельно.

[alibek]

[A11:C15].Value = [A1:C5].Value

[KL]

Это известный баг ( http://support.microsoft.com/default.as ... -ca;231090 ), который похоже жив и поныне в XL2003.
Попробуй так:

Код: Выделить всё

Sub Test1()
    Range("A678:R679").Copy
    Workbooks.Add
    With ActiveSheet.Range("A1")
        .PasteSpecial Paste:=8
        .PasteSpecial Paste:=xlValues
    End With
    Application.CutCopyMode = False
End Sub

или так:

Код: Выделить всё

Sub Test2()
    Dim rng As Range
    Set rng = Range("A678:R679")
    rng.Copy
    Workbooks.Add
    With ActiveSheet.Range("A1").Resize(rng.Rows.Count, rng.Columns.Count)
        .PasteSpecial Paste:=8
        .PasteSpecial Paste:=xlValues
    End With
    Application.CutCopyMode = False
End Sub

[Andrey_K]

Это известный баг ( http://support.microsoft.com/default.as ... -ca;231090 ), который похоже жив и поныне в XL2003.
Попробуй так:

Код: Выделить всё

Sub Test1()
    Range("A678:R679").Copy
    Workbooks.Add
    With ActiveSheet.Range("A1")
        .PasteSpecial Paste:=8
        .PasteSpecial Paste:=xlValues
    End With
    Application.CutCopyMode = False
End Sub

или так:

Код: Выделить всё

Sub Test2()
    Dim rng As Range
    Set rng = Range("A678:R679")
    rng.Copy
    Workbooks.Add
    With ActiveSheet.Range("A1").Resize(rng.Rows.Count, rng.Columns.Count)
        .PasteSpecial Paste:=8
        .PasteSpecial Paste:=xlValues
    End With
    Application.CutCopyMode = False
End Sub

О-о! Вот так работает, осталось победить высоту строк!
Есть предложения?!

[KL]

Код: Выделить всё

Sub Test2()
    Dim rng As Range
    Set rng = Range("A678:R679")
    rng.Copy
    Workbooks.Add
    With ActiveSheet.Range("A1").Resize(rng.Rows.Count, rng.Columns.Count)
        .PasteSpecial Paste:=8
        .PasteSpecial Paste:=xlValues
        For i = 1 To rng.Rows.Count
            .Rows(i).RowHeight = rng.Rows(i).RowHeight
        Next i
    End With
    Application.CutCopyMode = False
End Sub

[Andrey_K]

Kl - ну блин, волшебник. Я стока времени на это потратил, а все просто оказалось....
Пасибка!