Проблема доступа к Default Property в VB6

[uncle_gm]

Пусть имеется класс (например, ArrayClass), полем которого является массив:

Код: Выделить всё

Private mArr(24, 24) As Boolean

Public Property Get Arr(x As Byte, y As Byte) As Variant
Arr = mArr(x, y)
End Property

Public Property Let Arr(x As Byte, y As Byte, ByVal vNewValue As Variant)
Let mArr(x, y) = vNewValue
End Property

Причем, свойство Arr - Default Property

Тогда код,типа :

Код: Выделить всё

Dim tmp As New ArrayClass

tmp(0, 0) = True
tmp(1, 1) = True

Debug.Print "tmp(0, 0) =" & tmp(0, 0)
Debug.Print "tmp(1, 1) =" & tmp(1, 1)

работает без проблем. Т.е. без проблем производится присвоение и чтение элементов массива посредством Default Property - Arr.

Если же мы включаем ArrayClass в качестве поля данных в другой класс, например(ContClass):

Код: Выделить всё

Public mArrayClass As New ArrayClass

то попытка присвоения, типа:

Код: Выделить всё

Dim tmp As New ContClass

tmp.mArrayClass(0, 0) = True

вызывает ошибку времени во время исполнения "Wrong number of arguments or invalid property assignment".

Хотя чтение происходит без проблем:

Код: Выделить всё

debug.print "tmp.mArrayClass(0, 0)=" & tmp.mArrayClass(0, 0)

Проблема решается путем явного указания свойства:

Код: Выделить всё

tmp.mArrayClass.Arr(0, 0) = True

Но код при этом теряеи свою читабельность.

Это особенно заметно при большем уровне вложенности классов.

Кто-нибудь может подсказать способ решения данной проблемы?

[GSerg]

Код: Выделить всё

Let mArr(x, y) = vNewValue

Я думал, столь крепко держащихся за прошлое нет

Не знаю, стоит ли оставлять подобный вопрос в этом разделе
Ладно, пусть будет, хотя конечно да
Сделай в своём ContClass

Код: Выделить всё

Private mArrayClass As New ArrayClass

Public Property Get ArrayClass() As ArrayClass
  Set ArrayClass = mArrayClass
End Property

и пометь её как default.

[uncle_gm]

Оно бы конечно так, но если ContClass содержит несколько полей, аналогичных, ArrayClass, то где взять столько Default Properties ? .

На счет Let - проглотил. Понравилось.

Взялся он в коде после автоматической замены Set. Естественно ведь было попробовать, сохраняется ли проблема при использовании Property Set вместо Property Let ...
Так вот: проблема сохраняется...

[GSerg]

Оно бы конечно так, но если ContClass содержит несколько полей, аналогичных, ArrayClass, то где взять столько Default Properties ?

Аздиваисси, али как?
Вообще не назначай дефолтов тогда
ContClass

Код: Выделить всё

Option Explicit

Private mArrayClass1 As New ArrayClass
Private mArrayClass2 As New ArrayClass
Private mArrayClass3 As New ArrayClass

Public Property Get Foo1() As ArrayClass
  Set Foo1 = mArrayClass1
End Property

Public Property Get Foo2() As ArrayClass
  Set Foo2 = mArrayClass2
End Property

Public Property Get Foo3() As ArrayClass
  Set Foo3 = mArrayClass3
End Property

Код: Выделить всё

Private Sub Form_Load()
  Dim c As New ContClass
 
  c.Foo1(4, 4) = True
  c.Foo2(5, 5) = True
  c.Foo3(6, 6) = True
 
  MsgBox c.Foo1(4, 4)
  MsgBox c.Foo2(5, 5)
  MsgBox c.Foo3(6, 6)
 
End Sub

Естественно ведь было попробовать, сохраняется ли проблема при использовании Property Set вместо Property Let ...

Неееет, совершенно не естественно было попробовать Set для boolean... Это, однако, извращение...

[uncle_gm]

Да, действительно, если пользоваться свойствами во включаюжщем классе, то все работает.

Спасибо за совет.