Возвратить результат выполнения программы

[d3drm]

Добрый день, господа уважаемые.

Такой вот вопрос сегодня возник. Пишется утилита для распечатывания стикеров (маленьких наклеек на конверты) на VB. Ее задача - тупо распечатать переданный текст в нужном формате на нужном принтере. Программа вызывается через функцию exec php скрипта.

Задача - заставить программу выплюнуть в скрипт результат выполнения. Хоть 1 байт информации - удалось или нет? Подскажите, пожалуйста =)

[ANDLL]

Ага,WriteFile + GetStdHandle STD_OUTPUT_HANDLE

[Proxy]

А не прибегая к файлу как? (я не сталкивался с ПХП вообще никогда)

[ANDLL]

Вообще-то это как раз и есть "не прибегая к файлу"

[Proxy]

Ого.

[Хакер]

А ещё, кажется, потребуется править PE-header.

[ANDLL]

Тебе лишь бы чтото поправить. Ничего не придется
Кстати, дорогой мой, может ты поправишь хотя бы тот модуль который отправляет через SMTP что бы он не выводил ошибки а просто писал их в лог? А еще лучше переведи с mail.ru на скажем google mail

[Хакер]

ANDLL
Ты ошибаешься. Я бы рад ничего не править. Я всё-таки решил проверить:

• Я сделал exe-шник из следующего кода:
  

  Код: Выделить всё

  Private Const STD_OUTPUT_HANDLE = -11&
Private Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As Long
Private Declare Function WriteConsole Lib "kernel32" Alias "WriteConsoleA" (ByVal hConsoleOutput As Long, lpBuffer As Any, ByVal nNumberOfCharsToWrite As Long, lpNumberOfCharsWritten As Long, lpReserved As Any) As Long
Private Declare Function AllocConsole Lib "kernel32" () As Long

Public Sub Main()
    Dim x As String
    Dim n As Long
    x = "Hello Word!"
    n = Len(x)
    WriteConsole GetStdHandle(STD_OUTPUT_HANDLE), ByVal x, n, n, ByVal 0&
    MsgBox Err.LastDllError
End Sub

  
  и запустил его. Получил ошибку 6 (Неверный дескриптор).
  
• Я запустил его (exe-шник) из-под cmd.exe -- и схавал ту же ошибку.
• Я сделал в самом начале вызов AllocConsole, перекомпилировал EXE-шник и запустил его: Ошибки небыло, нужный текст отобразился в консоли.
• Я запустил exe-шник из-под cmd.exe -- при этом создалась новая консоль.
• Убрал вызов AllocConsole и таки поправил поле в PE-хеадере Subsystem c GUI на CUI (чтобы виндовый загрузчик аллочил консоль для нового процесса сразу же при загрузке): после этого, exe-шник стал работать как полагается.

Кажется, всё-таки, я прав?

А еще лучше переведи с mail.ru на скажем google mail

Знаешь ли, там отправка осуществляется через SSL. phpBB так не умеет.

[d3drm]

со всем что написано выше разобрался - в консоли файл выводит hello, word, но в функцию exec в пхп ничего не передается... Хакер, есть мысли какие-нибудь?


*UPD*
Из консоли программа работает нормально, из ехес'а выдает 6ую ошибку...

[ANDLL]

Кажется, всё-таки, я прав?

По приведенным пунктам - да. В главном - нет.
Раз d3 получает ответ в php, значит php сам создает трубу и передает ее в createprocess, иначе он никак не смог бы прочитать что вернула программа, верно?
Флажок sub system и наличие консоли у порождающего процесса имеет смысл, когда "мануальные трубы" в createprocess выставлены в null.
Во всех твоих случаях они выставлены в null, вот ты и видишь разницу.
Если вызывающая программа передает трубу, то именно ее вернет GetStdHandle, вне зависимости от флажков в заголовках. И писать в нее нужно через WriteFile, а не WriteConsole

Из консоли программа работает нормально, из ехес'а выдает 6ую ошибку..

Соответственно замени writeconsole на writefile

[d3drm]

Только собирался написать тут что проблема решилась заменой WriteConsole на WriteFile, как тут это сообщение =)

В общем все решилось, выражаю огромное спасибо пользователям Хакер, ANDLL, Proxy (первым двум за помощь в решении, последнему - за участие )

Вывод таков (обобщим):

для того, чтобы php скрипт мог читать выходные данные из программы на VB код должен выглядеть примерно следующи образом:

Код: Выделить всё

Private Const STD_OUTPUT_HANDLE = -11&

Private Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As Long
Public Declare Function WriteFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToWrite As Long, lpNumberOfBytesWritten As Long, lpOverlapped As Any) As Long



Public Sub Main()
    Dim x As String
    Dim n As Long
    x = "Hello Word!"
    n = Len(x)
    Dim nn As Long

    WriteFile GetStdHandle(STD_OUTPUT_HANDLE), ByVal x, n, nn, ByVal 0&

    MsgBox Err.LastDllError
End Sub


После этого следует задействовать какую-нибудь утилитку и сменить PE заголовок, без этого не работает - проверял. Сам использовал PE Tools v1.3 by NEOx.

Ну и в php обыкновенный ехес, данные выводятся в result и в массив out.