Отключение мыши над textbox в VB6

[shest]

Подскажите пожалуйста, как запретить TextBox реагировать на события мыши.
RichTextBox не подходит.
Заранее спасибо

[baha76]

Не пиши код на события мыши, вот и не будет он реагировать. А чтобы отключить указатель мыши над объектом, нужно событие MouseOver и там указатель нужно сделать невидимым.

[tyomitch]

Может быть, установить свойство Enabled в False достаточно?

[baha76]

Может быть, установить свойство Enabled в False достаточно?

Ну тогда Locked = True объязательно!

[shest]

Мне нужно, чтобы textbox был бы полностью функционален, но на мышь не реагировал. Курсор я погасил API функцией, но если щёлкать по полю, то контекстное меню выскакивает и пр. Тогда я написал Enabled в False на щелчок и отключал его через таймер, но это тоже не то.
На другом форуме посоветовали -BOOL ShowCaret(HWND hWnd) указываете hWnd текст бокса и все-.
Попытаюсь разобраться, но пока не понял, что это такое и как работает

[baha76]

Если при щелчке по полю выскакивает меню, значит работает событие MouseDown (или MouseUp, Click) TextBox-а Вот этот участок кода надо убрать.

[tyomitch]

Отключение всплывающего меню: http://www.vb-helper.com/howto_disable_text_popup.html

[shest]

Проверил ссылку на отключение меню-выкидывает ошибку выполнения. MouseDown , MouseUp, Click пробовал блокировать, но это не помогает

Код: Выделить всё

if button =2 then button= Empty

и пр.
В общем пока не нашёл решения кроме возни с таймером. ИМХО в VB это сделать нельзя, значит API -функция нужна. А кто-нибудь знает функцию не только курсор погасить, но отключить вообще мышь на время выполнения программы? Или просто отключить реакцию textBox на мышиные события?

[baha76]

Может выложишь код здесь? Загадка интересная становится...

[tyomitch]

Проверил ссылку на отключение меню-выкидывает ошибку выполнения.

NoPopupWindowProc должна быть в модуле (т.е. не в форме), с объявлениями:

Код: Выделить всё

Public Const GWL_WNDPROC As Long = -4
Public Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32.dll" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public OldWindowProc As Long


Предполагалось, что ты догадаешься

MouseDown , MouseUp, Click пробовал блокировать, но это не помогает

В смысле - не помогает блокировать меню? Так и не должно.

В общем пока не нашёл решения кроме возни с таймером. ИМХО в VB это сделать нельзя, значит API -функция нужна.

Тот код, на который я дал ссылку, вполне рабочий - только что проверил.

А кто-нибудь знает функцию не только курсор погасить, но отключить вообще мышь на время выполнения программы? Или просто отключить реакцию textBox на мышиные события?

В общем, ты тот код всё-таки посмотри. Его можно модифицировать в том смысле, что игнорировать не только WM_CONTEXTMENU, но и WM_LBUTTON* и т.п.

[shest]

Разместил функцию с объявлениями в модуле, разместил процедуры- не идёт. Может что опять не так?
Может пришлёшь на мыло проект (если не сложно )
shest@online.ru

[Шурик]

А ты скачай пример, там все понятно

[tyomitch]

Разместил функцию с объявлениями в модуле, разместил процедуры- не идёт. Может что опять не так?

Новый проект -> кидаю текстбокс на форму -> добавляю в форму код с http://www.vb-helper.com/howto_disable_text_popup.html -> добавляю модуль в проект -> добавляю в модуль объявления и код оттуда же. Готово!

[edit]2Шурик: а я и не заметил, что там кнопка Download была... [/edit]

[shest]

Ну получилось вроде.
Теперь бы найти функцию, которая полностью мышь отключит

[tyomitch]

Ну получилось вроде.
Теперь бы найти функцию, которая полностью мышь отключит

Без проблем, замени код модуля таким:

Код: Выделить всё

Option Explicit
Public Const GWL_WNDPROC = -4&
Public Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32.dll" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public OldWindowProc As Long

Private Const WM_MOUSEFIRST = &H200&
Private Const WM_MOUSELAST = &H209&

Public Function NoPopupWindowProc(ByVal hWnd As Long, ByVal _
    Msg As Long, ByVal wParam As Long, ByVal lParam As _
    Long) As Long

    Select Case Msg
    Case WM_MOUSEFIRST To WM_MOUSELAST:
        NoPopupWindowProc = 0
    Case Else:
        NoPopupWindowProc = CallWindowProc( _
            OldWindowProc, hWnd, Msg, wParam, _
            lParam)
    End Select
End Function

[shest]

Огромное спасибо tyomitch!
Вот это то, что нужно