Find Dialog Box

[Ruslan Demidow]

Как вызвать виндовый диалог "Поиск и замена"?
Читал в MSDN, да видимо, плохо читал - описано всё (передаваемые структуры и т.п.), а вот команду вызова или с помощью какой функции вызывается - не нашёл.
Подскажите, плиз, как открыть диалог.
А ещё лучше, если у кого примерчик в коде есть.
Спасибо.

[User2004]

A tebe imenno Windowskij nado?
Esli podojdet kod to vot:

Код: Выделить всё

'Sozdat' formu s : command button (command1), a list box (list1)
'4 text boxes (text1, text2, text3 and text4).
'V pervom textboxe- nachalnaja direktorija,naprimer  c:\
'Vo vtorom-shablon *.* , *.txt ,*.exe i t.p.

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

Const MAX_PATH = 260
Const MAXDWORD = &HFFFF
Const INVALID_HANDLE_VALUE = -1
Const FILE_ATTRIBUTE_ARCHIVE = &H20
Const FILE_ATTRIBUTE_DIRECTORY = &H10
Const FILE_ATTRIBUTE_HIDDEN = &H2
Const FILE_ATTRIBUTE_NORMAL = &H80
Const FILE_ATTRIBUTE_READONLY = &H1
Const FILE_ATTRIBUTE_SYSTEM = &H4
Const FILE_ATTRIBUTE_TEMPORARY = &H100

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
Function StripNulls(OriginalStr As String) As String
    If (InStr(OriginalStr, Chr(0)) > 0) Then
        OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
    End If
    StripNulls = OriginalStr
End Function

Function FindFilesAPI(path As String, SearchStr As String, FileCount As Integer, DirCount As Integer)

    Dim FileName As String
    Dim DirName As String
    Dim dirNames() As String ' Buffer
    Dim nDir As Integer ' Kolchestvo direktorij
    Dim i As Integer
    Dim hSearch As Long ' Search Handle
    Dim WFD As WIN32_FIND_DATA
    Dim Cont As Integer
    If Right(path, 1) <> "\" Then path = path & "\"
    ' Iskat' subdirectorii.
    nDir = 0
    ReDim dirNames(nDir)
    Cont = True
    hSearch = FindFirstFile(path & "*", WFD)
    If hSearch <> INVALID_HANDLE_VALUE Then
        Do While Cont
        DirName = StripNulls(WFD.cFileName)
        If (DirName <> ".") And (DirName <> "..") Then
            If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
                dirNames(nDir) = DirName
                DirCount = DirCount + 1
                nDir = nDir + 1
                ReDim Preserve dirNames(nDir)
            End If
        End If
        Cont = FindNextFile(hSearch, WFD) 'Get next subdirectory.
        Loop
        Cont = FindClose(hSearch)
    End If
    ' Podscitat' i ssumirovat' dlinu fajlov v directorii
    hSearch = FindFirstFile(path & SearchStr, WFD)
    Cont = True
    If hSearch <> INVALID_HANDLE_VALUE Then
        While Cont
            FileName = StripNulls(WFD.cFileName)
            If (FileName <> ".") And (FileName <> "..") Then
                FindFilesAPI = FindFilesAPI + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
                FileCount = FileCount + 1
                List1.AddItem path & FileName
            End If
            Cont = FindNextFile(hSearch, WFD) ' Get next file
        Wend
        Cont = FindClose(hSearch)
    End If
    If nDir > 0 Then
        For i = 0 To nDir - 1
            FindFilesAPI = FindFilesAPI + FindFilesAPI(path & dirNames(i) & "\", SearchStr, FileCount, DirCount)
        Next i
    End If
End Function
Sub Command1_Click()
    Dim SearchPath As String, FindStr As String
    Dim FileSize As Long
    Dim NumFiles As Integer, NumDirs As Integer
    Screen.MousePointer = vbHourglass
    List1.Clear
    SearchPath = Text1.Text
    FindStr = Text2.Text
    FileSize = FindFilesAPI(SearchPath, FindStr, NumFiles, NumDirs)
    Text3.Text = NumFiles & " Files found in " & NumDirs + 1 & " Directories"
    Text4.Text = "Size of files found under " & SearchPath & " = " & Format(FileSize, "#,###,###,##0") & " Bytes"
    Screen.MousePointer = vbDefault
End Sub


Esco sovetuju knopku <Cancel> sdelat' a mozno usnut' poka ona C:\ prosmotrit.
A dizajn formy mozno sdelat' kak hochesh.

[User2004]

"A tebe imenno Windowskij nado?
Esli podojdet kod to vot: "


(Ispugano)Ja,konecno,izviniajus,za nesobludenije subordinacii.
"Titul" tolko potom zametil.

[A.A.Z.]

А почему именно виндосовский? Ведь диалог "Поиск и замена" можно и самому быстренько настряпать

[Ruslan Demidow]

"A tebe imenno Windowskij nado?
Esli podojdet kod to vot: "


(Ispugano)Ja,konecno,izviniajus,za nesobludenije subordinacii.
"Titul" tolko potom zametil.

Да ладно
Причём тут титул?
Только ты меня неверно понял (или я не так выразил свою мысль).
Мне нужно искать не файлы, а слова в текте.

[Ruslan Demidow]

А почему именно виндосовский? Ведь диалог "Поиск и замена" можно и самому быстренько настряпать

Потому, что в нём уже заложен поиск "только целые слова". А если самому сделать, то мороки много.
Я, стати и сделал свой диалог, но вот вышел затык именно на поиске целых слов.