API запись в HKEY_CLASSES_ROOT с аргументами

Программирование на Visual Basic, главный форум. Обсуждение тем программирования на VB 1—6.
Даже если вы плохо разбираетесь в VB и программировании вообще — тут вам помогут. В разумных пределах, конечно.
Правила форума
Темы, в которых будет сначала написано «что нужно сделать», а затем просьба «помогите», будут закрыты.
Читайте требования к создаваемым темам.
giaber
Продвинутый пользователь
Продвинутый пользователь
 
Сообщения: 107
Зарегистрирован: 14.01.2009 (Ср) 13:51

API запись в HKEY_CLASSES_ROOT с аргументами

Сообщение giaber » 30.05.2019 (Чт) 14:36

Надо внести в HKEY_CLASSES_ROOT\Directory\shell\ свои записи.
Сечас я делаю это с помощью reg-файла (special thanks to Rius и Kogb!) :

Код: Выделить всё
Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\Directory\shell\FBFRenamerFolder]
@="FBFRenamerFolder"

[HKEY_CLASSES_ROOT\Directory\shell\FBFRenamerFolder\command]
@="\"C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe\" sub1 \"%1\""


моя прога получает аргумент sub1 и путь к моему exe-файлу

Но хочу чтоб прога при первом запуске сама вносила эти записи. После долгих поисков нашёл понятный для меня пример с API, но возникла проблема синтаксиса .
При внесении просто пути к моему exe-файлу всё ОК, но как сформировать строку с аргументами?

Код: Выделить всё
Private Sub CmdCreate_Click()
    '
    CreateNewKey HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder"
    '
    SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder", "FBFRenamerFolder", "FBFRenamerFolder", REG_SZ
    '
    CreateNewKey HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command"
    'Эти верхние три строки выполняются нормально
    'теперь в command надо вписать значене - путь к exe файлу и аргументы,
    'в reg-файле это выглядит так:
    '@="\"C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe\" sub1 \"%1\""
    'а здесь при вставке этой строки в таком виде VB6 не принимает и отмечает красным:
    SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command", "FBFRenamerFolderEXE", "\"C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe\" sub1 \"%1\"", REG_SZ
End Sub

как правильно сформировать строку?

ЗЫ
Способ с запуском reg-файла из проги мне известен, оставляю его на крайний случай, если на поднятый вопрос не получу ответа:
Код: Выделить всё
Shell "regedit.exe /s " & Chr(34) & "C:\Program Files (x86)\FBFRenamer\FBFRenamer.exe" & Chr(34)

ger_kar
Продвинутый гуру
Продвинутый гуру
Аватара пользователя
 
Сообщения: 1957
Зарегистрирован: 19.05.2011 (Чт) 19:23
Откуда: Кыргызстан, Иссык-Куль, г. Каракол

Re: API запись в HKEY_CLASSES_ROOT с аргументами

Сообщение ger_kar » 31.05.2019 (Пт) 11:09

SetKeyValue это обертка над Win API функциями? Приведи код (для полноты картины).
Далее откуда взялся "FBFRenamerFolderEXE"? Для установки значения по умолчанию нужно по идее передать пустую строку. Ну и само значение (строку) нужно сформировать с учетом синтаксиса VB например так:
"""C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe"" sub1 ""%1""" т.е. заменить последовательность символов \" на ""
Бороться и искать, найти и перепрятать

giaber
Продвинутый пользователь
Продвинутый пользователь
 
Сообщения: 107
Зарегистрирован: 14.01.2009 (Ср) 13:51

Re: API запись в HKEY_CLASSES_ROOT с аргументами

Сообщение giaber » 31.05.2019 (Пт) 19:04

2 ger_kar
“Далее откуда взялся "FBFRenamerFolderEXE"? Для установки значения по умолчанию нужно по идее передать пустую строку” – этого не знал :oops: , спасибо!
=====
Код: Выделить всё
Private Sub CmdCreate_Click()
    '
    CreateNewKey HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder"
    SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder", "FBFRenamerFolder", "FBFRenamerFolder", REG_SZ
    '
    CreateNewKey HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command"
‘Ваш вариант тоже не сработал:   
SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command", "FBFRenamerFolderEXE", """C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe"" sub1 ""%1""", REG_SZ"
    '
    '    ЭТО РАБОТАЕТ (но мне нужны аргументы!): SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command", "FBFRenamerFolderEXE", "C:\Program Files (x86)\FBFRenamer\FBFRenamer.exe", REG_SZ
    '
End Sub


HKEY_CLASSES_ROOT с аргументами.jpg


Модуль:
Код: Выделить всё
Public Const REG_SZ As Long = 1
Public Const REG_DWORD As Long = 4
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_USERS = &H80000003


Public Const ERROR_NONE = 0
Public Const ERROR_BADDB = 1
Public Const ERROR_BADKEY = 2
Public Const ERROR_CANTOPEN = 3
Public Const ERROR_CANTREAD = 4
Public Const ERROR_CANTWRITE = 5
Public Const ERROR_OUTOFMEMORY = 6
Public Const ERROR_INVALID_PARAMETER = 7
Public Const ERROR_ACCESS_DENIED = 8
Public Const ERROR_INVALID_PARAMETERS = 87
Public Const ERROR_NO_MORE_ITEMS = 259
Public Const KEY_ALL_ACCESS = &H3F
Public Const REG_OPTION_NON_VOLATILE = 0

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, ByVal lpSecurityAttributes As Long, phkResult As Long, lpdwDisposition As Long) As Long
Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Declare Function RegQueryValueExString Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long
Declare Function RegQueryValueExLong Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Long, lpcbData As Long) As Long
Declare Function RegQueryValueExNULL Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As Long, lpcbData As Long) As Long
Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpValue As String, ByVal cbData As Long) As Long
Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpValue As Long, ByVal cbData As Long) As Long
Declare Function RegDeleteKey& Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String)
Declare Function RegDeleteValue& Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) 'Создание нового ключа
Public Function CreateNewKey(lPredefinedKey As Long, sNewKeyName As String)
Dim hNewKey As Long
Dim lRetVal As Long
lRetVal = RegCreateKeyEx(lPredefinedKey, sNewKeyName, 0&, vbNullString, REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, 0&, hNewKey, lRetVal)
RegCloseKey (hNewKey)
End Function

'Запись данных в ключ
Public Function SetKeyValue(lPredefinedKey As Long, sKeyName As String, sValueName As String, vValueSetting As Variant, lValueType As Long)
Dim lRetVal As Long
Dim hKey As Long


lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = SetValueEx(hKey, sValueName, lValueType, vValueSetting)

RegCloseKey (hKey)
End Function

Public Function SetValueEx(ByVal hKey As Long, sValueName As String, lType As Long, vValue As Variant) As Long

Dim lValue As Long
Dim sValue As String

Select Case lType
Case REG_SZ
sValue = vValue
SetValueEx = RegSetValueExString(hKey, sValueName, 0&, lType, sValue, Len(sValue))
Case REG_DWORD
lValue = vValue
SetValueEx = RegSetValueExLong(hKey, sValueName, 0&, lType, lValue, 4)
End Select

End Function

'Возвращает значения записанные в ключе(т.е. чтение)
Public Function QueryValue(lPredefinedKey As Long, sKeyName As String, sValueName As String)

Dim lRetVal As Long
Dim hKey As Long
Dim vValue As Variant
lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = QueryValueEx(hKey, sValueName, vValue)
QueryValue = vValue
RegCloseKey (hKey)

End Function

Function QueryValueEx(ByVal lhKey As Long, ByVal szValueName As String, vValue As Variant) As Long

Dim cch As Long
Dim lrc As Long
Dim lType As Long
Dim lValue As Long
Dim sValue As String

On Error GoTo QueryValueExError

'Определение размера и типа считываемых данных
lrc = RegQueryValueExNULL(lhKey, szValueName, 0&, lType, 0&, cch)
If lrc <> ERROR_NONE Then MsgBox "Данных (ключа) не существует!", vbExclamation, Form1.Caption
Select Case lType
'Для символьных
Case REG_SZ:
sValue = String(cch, 0)
lrc = RegQueryValueExString(lhKey, szValueName, 0&, lType, sValue, cch)
If lrc = ERROR_NONE Then
vValue = Left$(sValue, cch)
Else
vValue = Empty
End If
'Для числовых
Case REG_DWORD:
lrc = RegQueryValueExLong(lhKey, szValueName, 0&, lType, lValue, cch)
If lrc = ERROR_NONE Then vValue = lValue
'Для остальных не поддержанных типов данных
Case Else
lrc = -1
End Select
QueryValueExExit:
QueryValueEx = lrc
Exit Function
QueryValueExError:
Resume QueryValueExExit
End Function

'Удаление значений ключа
Public Function DeleteValue(lPredefinedKey As Long, sKeyName As String, sValueName As String)
Dim lRetVal As Long
Dim hKey As Long
lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = RegDeleteValue(hKey, sValueName)
RegCloseKey (hKey)
End Function

'Удаление ключа
Public Function DeleteKey(lPredefinedKey As Long, sKeyName As String)
Dim lRetVal As Long
lRetVal = RegDeleteKey(lPredefinedKey, sKeyName)
End Function


ger_kar
Продвинутый гуру
Продвинутый гуру
Аватара пользователя
 
Сообщения: 1957
Зарегистрирован: 19.05.2011 (Чт) 19:23
Откуда: Кыргызстан, Иссык-Куль, г. Каракол

Re: API запись в HKEY_CLASSES_ROOT с аргументами

Сообщение ger_kar » 31.05.2019 (Пт) 19:50

giaber писал(а):‘Ваш вариант тоже не сработал:   SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command", "FBFRenamerFolderEXE", """C:\\Program Files (x86)\\FBFRenamer\\FBFRenamer.exe"" sub1 ""%1""", REG_SZ"

Ну ясен пень, что не сработает. На кой там после REG_SZ кавычка стоит? И опять же этот FBFRenamerFolderEXE передается вместо пустой строки.
И еще нужно заменить задвоенные слеши одинарными (в первом посте забыл про этот момент).
Вот так:
SetKeyValue HKEY_CLASSES_ROOT, "Directory\shell\FBFRenamerFolder\command", "", """C:\Program Files (x86)\FBFRenamer\FBFRenamer.exe"" sub1 ""%1""", REG_SZ
Все работает, не поленился - проверил.
Бороться и искать, найти и перепрятать

giaber
Продвинутый пользователь
Продвинутый пользователь
 
Сообщения: 107
Зарегистрирован: 14.01.2009 (Ср) 13:51

Re: API запись в HKEY_CLASSES_ROOT с аргументами

Сообщение giaber » 31.05.2019 (Пт) 20:05

ger_kar! БОЛЬШОЕ, БОЛЬШОЕ вам спасибо !!! Всё работает!


Вернуться в Visual Basic 1–6

Кто сейчас на конференции

Сейчас этот форум просматривают: AhrefsBot, Yandex-бот и гости: 17

    TopList  
cron