Помогите оптимизировать код программы

[DeQuick]

"Целочисленный одномерный массив из N элементов заполнить с кла-ры. Все максимальные элементы перенести в конец массива, а остальные элементы сдвинуть влево, сохраняя их относительное расположение. Пример: 8 3 2 8 7 1 2 8 0 -> 3 2 7 1 2 0 8 8 8.

Код: Выделить всё

Option Explicit
Private Sub Command1_Click()

Const N = 9
Dim A(1 To N) As Integer, i As Byte, j As Byte, s As Byte
Dim B(1 To N) As Byte, max As Long

For i = 1 To N
  A(i) = InputBox("введите " & i & "-й элемент массива", "Заполнение массива")
  lbl2.Caption = lbl2 & " " & A(i)
Next i


max = A(1)
s = 0
For i = 1 To N
  If A(i) > max Then
    max = A(i)
    s = 0
  End If
  If A(i) = max Then
    s = s + 1
    B(s) = i
  End If
Next i

For j = 1 To s
  For i = B(s - j + 1) To N - 1
      A(i) = A(i + 1)
      A(i + 1) = max
  Next i
Next j

lbl1.Caption = " "
For i = 1 To N
  lbl1.Caption = lbl1 & " " & A(i)
Next i

End Sub

[Viper] :: Пользуемся тэгами CODE!

[Alprog]

Можно так написать:

Код: Выделить всё

Option Explicit

Private Sub Command1_Click()
    Const N = 9
    Dim A(1 To N) As Integer, i As Integer, s As Integer, max As Integer
    For i = 1 To N
        A(i) = InputBox("введите " & i & "-й элемент массива", "Заполнение массива")
        lbl2.Caption = lbl2 & " " & A(i)
    Next i
   
    max = A(1)
    For i = 2 To N
        If A(i) > max Then max = A(i)
    Next i
   
    lbl1.Caption = " "
   
    For i = 1 To N
        If A(i) = max Then
            s = s + 1
        Else
            lbl1.Caption = lbl1 & " " & A(i)
        End If
    Next i
    For i = 1 To s
        lbl1.Caption = lbl1 & " " & max
    Next
End Sub

Переменные объявлены все как Integer.
За первый проход по массиву находим максимум, количество максимумов и их смещение нас не интересует.
За второй проход выводим сразу в лейбл все "не максимумы" и запоминаем сколько нам встретилось максимумов.
Ну и в самом конце добавляем столько максимумов, сколько нам встретилось.

[SSecurity]

ну максимум можно ещё на этапе ввода вычислить
после очередного

Код: Выделить всё

For i = 1 To N
  A(i) = InputBox("введите " & i & "-й элемент массива", "Заполнение массива")
  if I = 1 THEN
    Max = A(1)
  else
    if Max<A(i) THEN Max = A(i)
  end if
  lbl2.Caption = lbl2 & " " & A(i)
Next i


[DeQuick]

спасибо, работа и так зачлась. Но все равно сейчас переделаю. Кстати, как можно замерить время выполнения программы в VB6?
P.S. дааа... с типами я напутал, массив типа integer, а max - long, но в принципе, мне кажется, задача не подразумевает большое кол-во чисел в массиве.

[Alprog]

мне кажется, задача не подразумевает большое кол-во чисел в массиве

Дело не в этом. На сколько я знаю, на x86-ых быстрее выполняются операции с Integer'ом.

Кстати, как можно замерить время выполнения программы в VB6?

Простой способ:

Код: Выделить всё

Dim tim as Single
tim = timer
'Делаем долгие операции
msgbox timer - tim

Правда, твоя прога маленькая, а, значит, очень быстро выполняется.
Настолько быстро, что точности функции timer не хватает, чтобы заметить разницу во времени.

Для более точной замерки нужно использовать винапи.

[iGrok]

Дело не в этом. На сколько я знаю, на x86-ых быстрее выполняются операции с Integer'ом.

Боюсь, если разница и есть, на фоне всего остального она будет незаметна.

Для более точной замерки нужно использовать винапи.

Угу. Что-нить типа GetTickCount.

[Alprog]

Боюсь, если разница и есть, на фоне всего остального она будет незаметна.

Я очень старался оптимизировать

[SLIM]

Угу. Что-нить типа GetTickCount.

Ты что прикололся - использовать API для измерения времени выполнения...))))))

[Хакер]

Нет, ибо в этом нет ничего прикольного.

[SLIM]

Нет, ибо в этом нет ничего прикольного.

[offtopic]принципиально найду твой пост где и ты тоже говорил что замерять скорость с помощью API - это неправильно. А если постораться то и можно найти несколько других...[/offtopic]

[Хакер]

Найди

[SSecurity]

я думаю Timer вполне сгодится для данной программы .... или кто-то считает что найдется такой товарищ, который массив вручную будет за миллисекунды заполнять?:)))

во всяком случае можно замерить ту часть которая обработку производит ... ну а там что, - там лучше эту обработку в цикл поставить (до 100 например) и потом на 100 результат поделить, тока вот массив нужно будет запоминать - и к начальным условиям возвращать всегда - дл\ чичтоты эксперемента ))

[iGrok]

Угу. Что-нить типа GetTickCount.

Ты что прикололся - использовать API для измерения времени выполнения...))))))

А чего тут прикольного? ЗаDeclare'ить эту API - дело пары секунд. После пятого раза объявление запоминается наизусть, так что даже ни в какие справочники лезть не надо. Да и выдаёт она целые значения миллисекунд, в отличие от timer, дающего секунды "As Single". И вообще она (имхо) удобнее. )

во всяком случае можно замерить ту часть которая обработку производит ... ну а там что, - там лучше эту обработку в цикл поставить (до 100 например) и потом на 100 результат поделить, тока вот массив нужно будет запоминать - и к начальным условиям возвращать всегда - дл\ чичтоты эксперемента ))

Дык и при использовании более точного API тебе придётся обработку в цикл x100, а то и x1000 ставить.
Для 9 чисел она скорей всего займёт существенно меньше мс. Соответственно, "вчистую" её скорость ты стандартыми методами не измеришь.

[SSecurity]

я тут сложение проверял .... на скорость выполнения ... дык вот для результатат мне пришлось 200 млн итераций сверять ))))

[SLIM]

А чего тут прикольного? ЗаDeclare'ить эту API - дело пары секунд. После пятого раза объявление запоминается наизусть, так что даже ни в какие справочники лезть не надо. Да и выдаёт она целые значения миллисекунд, в отличие от timer, дающего секунды "As Single". И вообще она (имхо) удобнее. )

Да дело то не в этом - само использование API схавает кучу времени. Использовать наверное разве только для сравнительного анализа то да, можно

[iGrok]

Да дело то не в этом - само использование API схавает кучу времени.

Чего??
Может быть, ты имеешь в виду тот факт, что API, объявленная не через tlb, а при помощи Declare, при первом вызове будет работать медленно, за счёт того, что будут дополнительно выполняться LoadLibrary и GetProcAddress?
Ну так это будет ПЕРЕД первым вызовом, и на точность измерения времени никак не повлияет.

Или ты имеешь в виду что-то другое?

[SLIM]

Может быть, ты имеешь в виду тот факт, что API, объявленная не через tlb, а при помощи Declare

Yes. Не все же tlb имеет (кстати надо наконец скачать)...

Ну так это будет ПЕРЕД первым вызовом, и на точность измерения времени никак не повлияет.

Возможно я ошибкась гдето....

[Mikle]

Может кто-то удивится, но GetTickCounter работает с той же точностью, что и Timer. Для повышенной точности нужно использовать QueryPerformance.

[iGrok]

Может кто-то удивится, но GetTickCounter работает с той же точностью, что и Timer. Для повышенной точности нужно использовать QueryPerformance.

Да я в курсе уже. Просто GTC возвращает целое кол-во мс. As Long, а Timer - дробное кол-во секунд As Single. Но это уже вопрос удобства.

[vein]

Здавствуйте, кто может помогите пожалуйста. Программа работает полностью, но надо её оптимизировать.
так-с, задание. С клавиатуры вводится целочисленная матрица M x N. Надо вывести на экран номера столбцов, содержащих максимальное количество нулей. ( вся фишка в том что таких столбцов может быть несколько )
Вот код тут набросал:

Код: Выделить всё

Dim Am() As Integer
Dim M As Integer, N As Integer

Private Sub Command1_Click()
Dim av() As String, strAm As String
Dim i As Integer, j As Integer, k As Integer, KMAX As Integer
If Text2.Text <> "" And Text3.Text <> "" Then
  M = Val(Text2.Text) 'число строк
  N = Val(Text3.Text) 'число столбцов
  ReDim Am(M, N) ' размерность массива Am
  Picture1.Cls
  av = Split(Text1.Text) 'вводятся элементы массива Am
  KMAX = UBound(av) 'максимально возможное количество нулей в каком-либо столбце массива
   If M * N <> KMAX + 1 Then
    MsgBox ("Вы должны ввести все элементы матрицы")
     Exit Sub
   End If ' проверка правильности количества элементов массива
 
' массив av переводится в двумерный массив Am и выводится на экран
  k = 0
  For i = 0 To M - 1 'считаем по строкам
    strAm = ""
    For j = 0 To N - 1 'считаем по столбикам
      Am(i, j) = Val(av(k)) ' переводим массив av в массив Am
      strAm = strAm + "  " + Str(Am(i, j))
      k = k + 1
    Next
    Picture1.Print strAm 'вывод массива на экран
  Next
End If


End Sub

Private Sub Command2_Click()
Dim i As Integer, j As Integer, zero_count As Integer, MAX_ZEROS As Integer
Dim j_max() As Integer
ReDim j_max(N)
Dim astr As String

'вычисляем максимальное количество нулей в каком-либо столбце(ах) матрицы Am
  k = 0
  MAX_ZEROS = 0
  For j = 0 To N - 1 'считаем по строкам
    zero_count = 0
    For i = 0 To M - 1 'считаем по столбикам
      If Am(i, j) = 0 Then
        zero_count = zero_count + 1 'считаем количество нулей в столбиках
      End If
      If MAX_ZEROS < zero_count Then
        MAX_ZEROS = zero_count 'находим максимальное число нулей в каком-то столбике
        End If
    Next
  Next
  Label3.Caption = astr
 

k = 0
  For j = 0 To N - 1 'считаем по столбикам
    zero_count = 0
   For i = 0 To M - 1 'считаем по строкам
     If Am(i, j) = 0 Then
       zero_count = zero_count + 1
     End If
    If MAX_ZEROS = zero_count Then
     j_max(k) = j + 1
      k = k + 1
      Exit For
    End If
  Next
  Next
  For k = 0 To M
    If j_max(k) <> 0 Then
    astr = astr + "  " + Str(j_max(k))
    End If
  Next
   
  Label3.Caption = astr

End Sub


всем заранее благодарен
P.S. в принципе нужно оптимизировать последнюю часть кода, там где заполняется j_max() и выводится на экран, может его можно как-нибудь засунуть в циклы которые стоят выше его( в коде) ?

[SSecurity]

)) вывод в пикчербокс - это круто:)

как и в прежнем варианте - максимум нулей можно считать на этапе ввода информации
потом можно к примеру завести переменную текстовую в котороую сразу на этапе ввода параллельно со подсчетами записывать через запятую сколько нулей в строке / столбце (если нужно)

а потом просто разбить полученную переменную в массив
и индексы со значением равным максимальному будут соответсвовать номерам строк - т.е. то что нужно:)

Вообщем получается так:
Цикл 1 - от 0 до размерности av (одномерный).
Формирует матрицу (элементарные формулы перевода в строку/столбец).
тутже, можно считать количество нулей в строке (тогда сразу лучше создать одномерный массив xSize, размерностью в количество строк матрицы)
и тутже, можно считать максимум нулей по всем строкам
Цикл 2. Одномерный - проходит по циклу xSize и выводит индекс строк со значением равным максимуму