mouse_event

[d1337r]

У меня плохо работает событие mouse_move. Делал все по RTFM и MSDN, но на моем экране 1024*768 курсор попадает около верхнего левого угла экрана, то есть не там где надо

Код: Выделить всё

Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Const mabsolute = &H8000 '  absolute move
Private Const lmbdown = &H2 '  left button down
Private Const lmbup = &H4 '  left button up
Private Const mmbdown = &H20 '  middle button down
Private Const mmbup = &H40 '  middle button up
Private Const mmove = &H1 '  mouse move
Private Const rmbdown = &H8 '  right button down
Private Const rmbup = &H10 '  right button up

Private Sub Command1_Click()
movemouseto 790, 600
End Sub

Public Sub movemouseto(x As Long, y As Long)
Dim x1, y1 As Long
x1 = x * 65535 / Screen.Width
y1 = y * 65535 / Screen.Height
mouse_event (mmove + mabsolute), x1, y1, 0, 0

End Sub


[ALX_2002]

Прошу прощения, что отвечаю вопросом на вопрос, но всё же:

А SetCursorPos не подходит по каким то причинам ?

Она координаты в пикселах вроде как принимает

[AntonGV]

d1337r
Не работает, потому что Screen.Width и Screen.Height возвращают размеры экрана в твипах.
Должно быть так:

Код: Выделить всё

Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Declare Function GetMessageExtraInfo Lib "user32" () As Long
Private Const mabsolute = &H8000 '  absolute move
Private Const lmbdown = &H2 '  left button down
Private Const lmbup = &H4 '  left button up
Private Const mmbdown = &H20 '  middle button down
Private Const mmbup = &H40 '  middle button up
Private Const mmove = &H1 '  mouse move
Private Const rmbdown = &H8 '  right button down
Private Const rmbup = &H10 '  right button up

Private Sub Command1_Click()
  MoveMouseTo 790, 600
End Sub

Public Sub MoveMouseTo(x As Long, y As Long)
  Dim x1, y1 As Long
  x1 = x * 65535 / (Screen.Width / Screen.TwipsPerPixelX)
  y1 = y * 65535 / (Screen.Height / Screen.TwipsPerPixelY)
  mouse_event mmove Or mabsolute, x1, y1, 0, GetMessageExtraInfo()
End Sub

[Arcady_XQST]

Не работает, потому что Screen.Width и Screen.Height возвращают размеры экрана в твипах.

Код: Выделить всё

Private Sub Form_Load()
    MsgBox Screen.Width / 15 & "x" & Screen.Height / 15
End Sub

А так?

[Хакер]

Arcady_XQST
А не так. 1твип не всегда = 15 пикселям.

[EUGY]

Немножко наоборот: 15 твипов не всегда = 1 пикселю

[burik]

Код: Выделить всё


Private Sub Form_Load()
    MsgBox Screen.Width / Screen.TwipsPerPixelX & "x" & Screen.Height / Screen.TwipsPerPixelY
End Sub


[Arcady_XQST]

А от чего зависит количество твипов на 1 пискель?

[Хакер]

Панель управления -> Экран -> Вкладка "Параметры" -> Кнопка "Дополнительно" -> Масштаб (кол-во точек на дюйм).