сборка чисел на vb

[mcnick]

я тут доставал народ сборкой double и понял, что надо упростить задачку. допустим приходят два байта:st_bayt - старший байт и ml_bayt - младший байт. мне надо объеденить их в integer.
я пишу код как на ассемблере:
word = st_bayt 'пишу в integer старший байт
word = word *256 'сдвигаю его на место старших разрядов- на 8 бит
word = word or ml_bayt ' объединяю его с младшим байтом
код работает, но только с положительными числами. если число приходит отрицательное, т.е. в дополнительном коде, код не реботает.
вопрос: как правильно объеденить два байта в integer.
когда гуру от vb решат это, может станет понятно и с double.
что до числа байт в double, то пусть будет 8. но вопрос остается - как их правильно распределить, если они приходят побайтно.
mcnick.

[tyomitch]

LSet устроит?

[Хакер]

mcnick
Следует использовать PutMem1.

[Random]

(даже не помню кто автор,только что он какой-то американец Джон). Данный код иллюстрирует способ создания новго типа данных:
=============================================

Код: Выделить всё

'Creating a New Data Type
'Class UInt module level
'Provides an unsigned integer type
'Methods:
'   None
'Properties:
'   Value (default)
'   HiByte
'   LoByte

'Type structures used for returning high/low bytes
Private Type UnsignedIntType
    lo As Byte
    hi As Byte
End Type

Private Type SignedIntType
    n As Integer
End Type

'Internal variables for returning high/low bytes
Private mnValue As SignedIntType
Private muValue As UnsignedIntType

Property Let Value(lIn As Long)
    mnValue.n = (lIn And &H7FFF&) - (lIn And &H8000&)
    LSet muValue = mnValue
End Property

Property Get Value() As Long
    Value = mnValue.n And &HFFFF&
End Property

Property Let HiByte(bIn As Byte)
    muValue.hi = bIn
    LSet mnValue = muValue
End Property

Property Get HiByte() As Byte
    LSet muValue = mnValue
    HiByte = muValue.hi
End Property

Property Let LoByte(bIn As Byte)
    muValue.lo = bIn
    LSet mnValue = muValue
End Property

Property Get LoByte() As Byte
    LSet muValue = mnValue
    LoByte = muValue.lo
End Property

Using the New Data Type
Be sure to set Value to be the default property of the UInt class

Код: Выделить всё

Option Explicit
Private Sub Form_Click()
    Dim uNewVar As New UInt
    'Set the default property
    uNewVar = 64552
    'Set the high byte
    uNewVar.HiByte = &HFF
    'Return the low byte
    Print Hex(uNewVar.LoByte)
End Sub


[GSerg]

В чём смысл этого кода?
Повторить (в форме класса! ужос какой) тот код, который очень давно лежит в Кирпичах?

[HiSER]

Код: Выделить всё

Private Declare Sub CopyMemoryByVal Lib "kernel32" Alias "RtlMoveMemory" (ByVal Destination As Long, Source As Any, ByVal Length As Long)
Private Declare Sub CopyMemoryByRef Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Private Sub Command1_Click()
Dim bl As Byte
Dim bh As Byte
Dim i As Integer

bl = 0
bh = 255

CopyMemoryByVal VarPtr(i), bl, 1
CopyMemoryByVal VarPtr(i) + 1, bh, 1

Me.Caption = i
End Sub

Private Sub Command2_Click()
Dim b(1) As Byte
Dim i As Integer

b(0) = 0 'l
b(1) = 255 'h

CopyMemoryByRef i, b(0), 2

Me.Caption = i
End Sub


[Хакер]

-=}-{i$ER=-
http://bbs.vbstreets.ru/viewtopic.php?t=13432

[GSerg]

-=}-{i$ER=-, помимо прочего, выбери себе нормальный ник. И сообщи его Хакеру или RayShade, чтобы тебе его поменяли.
Иначе будет бан.