Код возврата модального окна?

[Kaa]

Продолжу, с вашего разрешения, задавать "чайницкие" вопросы.

Можно-ли запустить свою форму в модальном режиме и получить обратно код возврата а-ля MsgBox? Насколько я понял, метод Show не возвращает ничего, да и куда присвоить этот код возврата? Есть-ли стандартные средства, а то мне ничего проще, чем:

Код: Выделить всё

Private ModalResult As Integer

Public Function ShowModal() As Integer
  Me.Show vbModal
  ShowModal = ModalResult
End Function

Private Sub btnCancel_Click()
  ModalResult = vbCancel
  Unload Me
End Sub

Private Sub btnOK_Click()
  ModalResult = vbOK
  Unload Me
End Sub

в голову не приходит.

[alibek]

На форме (frmTest):

Код: Выделить всё

Option Explicit

Private Sub cmdCancel_Click()
Tag = "CANCEL"
Hide
End Sub

Private Sub cmdOK_Click()
Tag = "OK"
Hide
End Sub

Private Sub Form_Load()
Tag = vbNullString
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
If UnloadMode = QueryUnloadConstants.vbFormControlMenu Then
  Cancel = True
  cmdCancel_Click
End If
End Sub


Вызов:

Код: Выделить всё

Dim res As Boolean
res = GetFormResult()
MsgBox "Result: " & IIf(res,"OK","CANCEL")

...

Function GetFormResult() As Boolean
Load frmTest
'Form initialization
With frmTest
  .Caption = "Test"
End With
frmTest.Show vbModal
GetFormResult = (frmTest.Tag = "OK")
Unload frmTest
Set frmTest = Nothing
End Function


[Kaa]

А чем этот вариант (как я понял, встроенных возможностей нема) лучше? Мой вариант имхо проще и понятнее. Это ни в коем разе не наезд. Мой уровень в VB пока чуть выше плинтуса и я возможно не заметил каких-то граблей в своем варианте.

Слегка подправил код:

Код: Выделить всё

Option Explicit

Private ModalResult As Integer

Public Function ShowModal() As Integer
  Me.Show vbModal
  ShowModal = ModalResult
End Function

Private Sub btnCancel_Click()
  ModalResult = vbCancel
  Unload Me
End Sub

Private Sub btnOK_Click()
  ModalResult = vbOK
  Unload Me
End Sub

Private Sub Form_Load()
  ModalResult = vbCancel
End Sub

Для вызова:

Код: Выделить всё

  If frmTest.ShowModal = vbOK Then
    Label1.Caption = "OK"
  Else:
    Label1.Caption = "Someting Wrong"
  End If


[alibek]

Он не лучше, просто в этом способе не используются глобальные переменные.