Как отслеживать перемещения окна

[Wolfie]

Приветствую!
Есть такая задачка - нужно запоминать позицию окна - сохранять ее в реестр, вроде просто - сейвь перед выходом Top и Left и хорошо... но окно можно закрыть из свернутого режима или развернутого - тогда эти топ и лефт имеют, кхм, не те значения... Стартует же программа всегда в Нормальном режиме окна, т.е. сохранять WindowState не выход... короче проблема - как мне отслеживать премещения окна по экрану, чтобы сразу после перемещения в переменные сейвить Топ и Лефт... может я туплю, но никак не пойму как мне решить проблему... Подскажите пожалуйста

[Cytron]

нмм ты сохраняй топ и лефт при перемещении если виндоустэйт равен 0

Код: Выделить всё


If Windowstate = 0 Then
' Сохраняем в реестр
End If


итого у тебя в реестр запишется всегда последнее значение позиции проги в нормальном режиме окна

[EUGY]

может где-то там.
GetWindowPlacement / WINDOWPLACEMENT / rcNormalPosition

[Twister]

Если окно принадлежит твоему процессу, то особых проблем отследить его положение и состояние не возникает. Чуть больше усилий необходимо, чтоб следить за чужими окнами...

[Wolfie]

нмм ты сохраняй топ и лефт при перемещении если виндоустэйт равен 0

спасибо, но я именно это делать собираюсь, только с переменными а не с реестром - вопрос как раз в том - КАК мне следить за перемещением окна, ведь нет же события Move...
EUGY взять координаты можно и обычным .Top .Left, вопрос в том - КОГДА нужно их взять, когда нужно сделать

Код: Выделить всё

If Not WindowState Then
SvT=Me.Top
SvL=Me.Left
End If

?
Twister процесс то мой, но может, все же, Вы подробнее раскроете свой ответ?

[EUGY]

Dim wpl As WINDOWPLACEMENT
GetWindowPlacement Me.hwnd, wpl
Debug.Print wpl.rcNormalPosition.Top

rcNormalPosition будет содержать нужные данные независимо от WindowState, даже если окно свернуто. Это и сохраняй перед выходом, только преобразуй в твипы: wpl.rcNormalPosition.Top * 15 == Me.Top

Код: Выделить всё


Option Explicit
Private Type POINTAPI
        x As Long
        y As Long
End Type
Private Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type
Private Type WINDOWPLACEMENT
        Length As Long
        flags As Long
        showCmd As Long
        ptMinPosition As POINTAPI
        ptMaxPosition As POINTAPI
        rcNormalPosition As RECT
End Type
Private Declare Function GetWindowPlacement Lib "user32" (ByVal hwnd As Long, lpwndpl As WINDOWPLACEMENT) As Long

Private Sub Form_Unload(Cancel As Integer)
Dim SvT As Integer
Dim SvL As Integer
Dim wpl As WINDOWPLACEMENT
    GetWindowPlacement Me.hwnd, wpl
    SvT = wpl.rcNormalPosition.Top * 15
    SvL = wpl.rcNormalPosition.Left * 15
End Sub


Ну, вот, как-то так.[/syntax]

[Cytron]

ведь нет же события Move...

Да, но есть событие resize, которое воспроизводится при перемещении.
Обьясни все по порядку, я не совсем понимаю что именно тебе нужно.

[VB-constructor]

которое воспроизводится при перемещении.

разве?

я тоже так сначала подумал, но когда проверил, оказалось, что нет

[Wolfie]

EUGY большое спасибо - за подсказку и код - все сделал - работает как надо Только мне кажется, для преобразования в Твипы, на всякий случай, стоит использовать Screen.TwipsPerPixelX и Y

Cytron Никакого события при перемещении не происходит...
Ну все уже решено, однако, в событии Resize можно следить за изменением лишь ширины и высоты окна, и соответсвенно при WindowState=0 'Normal можно сейвить эти данные в переменные и при выходе в режиме WindowState<>0 сохранить в реестр не Me.Top и Me.Left, которые имеют совсем не те данные, а сохраненные заранее в событии Resize; но как таким способом сохранять Normal .Top .Left ? Короче EUGY предложил не следить а получить готовое.

Всем спасибо за внимание

[Kostyan]

Так, для справки, перемещение окна можно отловить по сообщениям WM_MOVE и WM_MOVING.
Это в форму:

Код: Выделить всё

Private Sub Form_Load()
SetProc Form1.hwnd
End Sub

Private Sub Form_Unload(Cancel As Integer)
Call SetWindowLong(Me.hwnd, -4, lngOldProc)
End Sub

Это в модуль:

Код: Выделить всё

Public Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type

Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long

Public Const WM_MOVING = &H216
Public Const WM_MOVE = &H3

Public lngOldProc As Long, R As RECT

Public Sub SetProc(ByVal lngHandle As Long)
lngOldProc = SetWindowLong(lngHandle, -4, AddressOf WinProc)
End Sub

Private Function WinProc(ByVal lngHandle As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
If Msg = WM_MOVING Or Msg = WM_MOVE Then
    Call GetWindowRect(Form1.hwnd, R)
    Form1.Caption = R.Left & " - " & R.Top
End If
WinProc = CallWindowProc(lngOldProc, lngHandle, Msg, wParam, lParam)
End Function

[Wolfie]

Kostyan спасибо, сохраню на будущее