Кликнуть мышкой на объект??

[Scuder]

Есть OCX, кладу его на форму. При клике на него производятся определённые действия. Мне нужно, чтобы не пользователь на него кликал, а программа. Но у него даже hwnd нет. Как на него кликнуть можно по-хорошему?

[tyomitch]

mouse_event?

[Scuder]

А передаваемые в функцию координаты после выполнения реально меняются?

[tyomitch]

Нет, конечно - они же передаются ByVal

[Scuder]

http://bbs.vbstreets.ru/viewtopic.php?t ... mouseevent

Не работает.
Если в модуле пишу так:

Код: Выделить всё

Public Enum MouseButtonsClick
mbtnLeft = 6
mbtnMiddle = 96
mbtnRight = 24
End Enum

И вызываю так:

Код: Выделить всё

MouseClick 9970, 3370, mbtnLeft

ругается на Ambiguous name detected: mbtnLeft

А если так:

Код: Выделить всё

MouseClick 9970, 3370, 6

то ничего не происходит..

9970 и 3370 - координаты контрола (+10).

[tyomitch]

координаты надо в пикселах давать, а не твипах
и относительно экрана, а не окна

[Scuder]

Ничего не происходит..
Уже растянул его на весь экран.

Код: Выделить всё

MouseDown 500, 500, 2
Sleep 2000
MouseUp 500, 500, 4

Даже так не работает..

[GSerg]

Sleep-то зачем?

[Scuder]

Потому что никак не работает..

Так тоже:

Код: Выделить всё

mouse_event 6, 50, 50, 0&, 0&

И так:

Код: Выделить всё

MouseClick 50, 50, 6

[ALX_2002]

Может я чего то недопонял, но по ходу, прога ругается на наличие такого же объекта как mbtnleft - Ambiguous name detected: mbtnLeft ?

[Scuder]

Ругается. Такое ощущение, что это зарезервированное имя..
Потому что на mbtnLeftqqq она уже не ругается.. Но дело не в этом. Делаю одну большую кнопку на всю форму. Форму - на весь экран. Делаю вторую кнопку (маленькую). При нажатии на неё должна нажиматься большая. Не получается..

[tyomitch]

Вот работающая версия: (Command1 маленькая в левом верхнем углу формы, Command2 большая на весь экран)

Код: Выделить всё

Option Explicit

Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliSeconds As Long)

Private Enum MouseButtons
Left = 2
Middle = 32
Right = 8
End Enum

Private Sub MouseDown(ByVal MouseButton As MouseButtons)
mouse_event MouseButton, 0, 0, 0&, 0&
End Sub

Private Sub MouseUp(ByVal MouseButton As MouseButtons)
mouse_event MouseButton * 2, 0, 0, 0&, 0&
End Sub

Private Sub MouseClick(ByVal MouseButton As MouseButtons)
MouseDown MouseButton
MouseUp MouseButton
End Sub

Private Sub MouseMove(ByVal X As Long, ByVal Y As Long)
mouse_event 1, X, Y, 0&, 0&
End Sub

Private Sub MouseClickAt(ByVal X As Long, ByVal Y As Long, ByVal MouseButton As MouseButtons)
MouseMove X, Y
MouseClick MouseButton
MouseMove -X, -Y
End Sub

Private Sub Command1_Click()
MouseClickAt 50, 50, Left
End Sub

Private Sub Command2_Click()
MsgBox "!"
End Sub


Ошибка в коде AAZ - из-за того, что одинаковые имена даны членам разных енумов. Чтобы их использовать, нужно писать явно, напр. MouseButtonsUp.mbtnLeft

[Scuder]

tyomitch, спасибо большое! А то я уж подумал, что мне совсем не везёт в этой жизни..