А в VB есть родные функции для перекодировки WIN <-> D

[PSV]

Хаюшки!

А в VB есть родные функции для перекодировки WIN <-> DOS (ANSI <-> OEM) типа API-ых CharToOEM, OEMToChar?

[SHURUP]

Родных нет (хотя как по мне и CharToOEM, OEMToChar не чужие), но можно правильным алгоритмом организовать замену!

[Andrey Fedorov]

А ведь если по хорошему, то все что через API-это тоже родное.
"Неродное" - это когда используются дополнительные OCX/DLL, не входящие в состав Windows.

[timsoft]

я лет семь назад сам писал функцию, нашел в архиве

может пригодится

Код: Выделить всё

Public Function toWin(S As String) As String
  Dim i As Long, wrk As String, ch As Byte
  wrk = ""
  For i = 1 To Len(S)
    ch = Asc(mid(S, i, 1))
    If ch <= 127 Then wrk = wrk + Chr(ch)
    If ch >= 127 And ch <= 175 Then wrk = wrk + Chr(ch + 64)
    If ch >= 176 And ch <= 191 Then wrk = wrk + Chr(ch)
    If ch >= 192 And ch <= 223 Then wrk = wrk + Chr(ch - 64)
    If ch >= 224 And ch <= 239 Then wrk = wrk + Chr(ch + 16)
    If ch >= 240 And ch <= 255 Then wrk = wrk + Chr(ch - 80)
  Next i
  toWin = wrk
End Function


конвертит из ДОС в ВИН

[Andrey Fedorov]

я лет семь назад сам писал функцию, нашел в архиве

На больших строках будут громадные тормоза.
Лучше преобразовать твою функцию (она, кстати, не полный аналог OemToChar) к виду:

Код: Выделить всё

Public Function VbOemToChar(ByVal s As String) As String
    Dim j As Long, i As Long

    For i = 1 To Len(s)
        j = Asc(Mid$(s, i, 1))
        Select Case j
            Case Is <= 127
            Case 128 To 175: Mid$(s, i, 1) = Chr$(j + 64)
            Case 176 To 191: Mid$(s, i, 1) = Chr$(j)
            Case 192 To 223: Mid$(s, i, 1) = Chr$(j - 64)
            Case 224 To 239: Mid$(s, i, 1) = Chr$(j + 16)
            Case Else:       Mid$(s, i, 1) = Chr$(j - 80)
        End Select
    Next i
    VbOemToChar = s
End Function

Тогда хоть разница в скорости будет ~10 раз (в NativeCode)

А вообще я так-же несколько лет назад из интереса писал аналог - мне удалось добиться разницы с OemToChar ~1.5 раза. Но там принцип был на обработке байтового массива...

[Andrey Fedorov]

Да, а вот так еще чуть быстрей:

Public Function VbOemToChar(ByVal s As String) As String
Dim j As Long, i As Long

For i = 1 To Len(s)
j = Asc(Mid$(s, i, 1))
Select Case j
Case Is <= 127
Case Is <= 175: Mid$(s, i, 1) = Chr$(j + 64)
Case Is <= 191: Mid$(s, i, 1) = Chr$(j)
Case Is <= 223: Mid$(s, i, 1) = Chr$(j - 64)
Case Is <= 239: Mid$(s, i, 1) = Chr$(j + 16)
Case Else: Mid$(s, i, 1) = Chr$(j - 80)
End Select
Next i
VbOemToChar = s
End Function