Как обратиться ко всем Control в конкретной SSTab.Tab?

[Rojohn]

Кстати, я где-то видел процедурку/класс перебирающую контролы на форме и исправляющую баг фреймов...

Полезная наверное процедурка, если она ещё и SSTab.Tab перебирает, то нужен намёк как и где её найти. А то с TabStrip слишком мучительно и ненаглядно, несмотря на все его достоинства...

[Rojohn]

http://www.gasanov.net/Download/XPFrame.zip

Для меня пока ента штука больно непонятная, но подозреваю, что она идёт только на NT подобных операционках...

[Andrey Fedorov]

http://www.gasanov.net/Download/XPFrame.zip

Не - там именно использовались стандартные фрэймы, чем и было интересно...

[GSerg]

А здесь вообще просто пустой контрол.
Это гораздо проще.

И работать он будет везде, надо просто чуть доработать функцию Themed. Включить обработку отсутствия функции в библиотеке.

[Andrey Fedorov]

А здесь вообще просто пустой контрол.
Это гораздо проще.

А как быть при этом с тем что уже написано?

В общем, нашел я ту функцию - оказалось что она просто вставляет PictureBox-ы:

Код: Выделить всё

Private Declare Function SetParent Lib "user32.dll" ( _
                ByVal hWndChild As Long, _
                ByVal hWndNewParent As Long) _
                As Long
Private Declare Function LockWindowUpdate Lib "user32.dll" ( _
                ByVal hwndLock As Long) _
                As Long

'****************************************************************************************
'METHODS - PUBLIC
'****************************************************************************************

Public Sub FixFramedControls(ByRef frm As Form)
    'Purpose:       to cause command buttons and option buttons conatined inside frames
    '               to appear the way that they are supposed to under Windows XP
    'Parameters:    frm - reference to the form that contains the control
    Dim ctl As Control
    Dim ctlChild As Control
    Dim Pic As PictureBox
    Dim lIdx As Long
    Dim lXBorder As Long
    Dim lYBorder As Long
    Dim lLeft As Long
    Dim lTop As Long
    Dim lWidth As Long
    Dim lHeight As Long
    Dim lCnt As Long
   
    On Error GoTo ErrHandler
   
    LockWindowUpdate frm.hWnd
   
    For Each ctl In frm.Controls
        If TypeOf ctl Is Frame Then
            lCnt = lCnt + 1
            'add a picture box inside the frame to contain the controls
            Set Pic = frm.Controls.Add("VB.PictureBox", "picHolder" & lCnt, frm)
           
            'make sure the picture box is at top of zorder and has properties we want
            Pic.Appearance = 0
            Pic.BorderStyle = 0
            Pic.Visible = True
           
            'now check each control to see if it is a child of the frame
            For Each ctlChild In frm.Controls
                If TypeOf ctlChild Is CommandButton Or _
                        TypeOf ctlChild Is OptionButton Then
                    If ctlChild.Container Is ctl Then
                        With ctlChild
                            'set the control to be a child of the picture box
                            Call SetParent(.hWnd, Pic.hWnd)
                           
                            'find the bounding rectangle for the size of the picture box
                            If lLeft = 0 Then
                                lLeft = .Left
                            Else
                                If lLeft > .Left Then
                                    lLeft = .Left
                                End If
                            End If
                            If lTop = 0 Then
                                lTop = .Top
                            Else
                                If lTop > .Top Then
                                    lTop = .Top
                                End If
                            End If
                            If lWidth = 0 Then
                                lWidth = .Width + .Left
                            Else
                                If lWidth < .Width + .Left Then
                                    lWidth = .Width + .Left
                                End If
                            End If
                            If lHeight = 0 Then
                                lHeight = .Top + .Height
                            Else
                                If lHeight < .Top + .Height Then
                                    lHeight = .Top + .Height
                                End If
                            End If
                        End With
                    End If
                End If
                Pic.Move lLeft, lTop, lWidth - lLeft, lHeight - lTop
            Next ctlChild
           
            'size the picture box accordingly to encompass all controls contained in the
            'frame without accidentally drawing over the frame
            'NOTE: this is assuming that the developer has not placed control overlapping
            'the frame already
            Call SetParent(Pic.hWnd, ctl.hWnd)
            Pic.ZOrder 1
           
            'now position the control inside the picture box
            For Each ctlChild In frm.Controls
                If TypeOf ctlChild Is CommandButton Or _
                        TypeOf ctlChild Is OptionButton Then
                    If ctlChild.Container Is Pic Then
                        With ctlChild
                            .Left = .Left - lLeft
                            .Top = .Top - lTop
                        End With
                    End If
                End If
            Next ctlChild
        End If
        lLeft = 0
        lTop = 0
        lWidth = 0
        lHeight = 0
    Next ctl
   
ExitProc:
    'clean up and exit
    LockWindowUpdate 0&
    Exit Sub
   
ErrHandler:
    Debug.Print Err.Number & ": " & Err.Description
    Resume ExitProc
End Sub


[Rojohn]

Занимательная функция, но к SSTab.Tab она никак не относится... Лучше сделаю-ка я так как Большой человек:) говорил про TabStrip, тока использую вместо TabStrip SSTab Если не считать некоторых неудобств разработчика (то есть меня), то вроде и юзеры сыты и овцы целы!

[Worobjoff]

Мучился с этим SSTab то же. Долго не мог найти способ, чтобы код ресайзинга почеловечнее получался.
Потом нашел C1Tab от ComponentOne. Все проблемы сразу решились.

Здесь пример для MS SSTab, который может быть прогодится.
(специально для форума почистил код своей "лабораторной работы")