Можно выключить комп?

[mefestofele]

Возможно ли в скрипте VB набрать команду выключающую компьютер
_________________
Да поможет тебе F1, Да сохранит тебя F2. Во имяя ALT'a, SHIFT'a и свяятого DEL'a, ESC.

[gaidar]

Const EWX_LOGOFF = 0
Const EWX_SHUTDOWN = 1
Const EWX_REBOOT = 2
Const EWX_FORCE = 4

Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long

Private Sub Form_Load()
msg = MsgBox("Вырубаемся?", vbCritical + vbOKCancel + 256, App.Title)
If msg = vbCancel Then End
ret& = ExitWindowsEx(EWX_FORCE Or EWX_SHUTDOWN, 0)
End Sub

[mefestofele]

Может вы меня не правильно поняли
Я пишу программу каторая проведёт дифрагментайию
И через 6 часов вырубит комп
Чтобы на утро он был бы свежим

_________________
Да поможет тебе F1, Да сохранит тебя F2. Во имяя ALT'a, SHIFT'a и свяятого DEL'a, ESC.

[alibek]

Если система на основе NT (2000, XP), то предварительно нужно получить соответствующую привилегию. Пример - в API-Guide.

[*Qwerty*]

:twisted: Возможно ли в скрипте VB набрать команду выключающую компьютер
_________________
Да поможет тебе F1, Да сохранит тебя F2. Во имяя ALT'a, SHIFT'a и свяятого DEL'a, ESC.

А я вот подумал, а не проще ли воспользоваться функцией Shutdown в Видовз, а именно:

Shell ("Shutdown -s")

Вот и всё, и не надо больших програмных кодов!!!

[Tarik]

Лично я не уверен, что Shutdown есть в Win 9x

[A.A.Z.]

Код: Выделить всё

'In a module
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Type LUID
    LowPart As Long
    HighPart As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub
' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_SHUTDOWN
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Restart NT
Public Sub RebootNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_REBOOT
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Log off the current user
Public Sub LogOffNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_LOGOFF
    If Force Then Flags = Flags + EWX_FORCE
    ExitWindowsEx Flags, 0
End Sub

'In a form
'This project needs a form with three command buttons
Private Sub Command1_Click()
    LogOffNT True
End Sub
Private Sub Command2_Click()
    RebootNT True
End Sub
Private Sub Command3_Click()
    ShutDownNT True
End Sub
Private Sub Form_Load()
    'KPD-Team 2000
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Command1.Caption = "Log Off NT"
    Command2.Caption = "Reboot NT"
    Command3.Caption = "Shutdown NT"
End Sub

[**Black-Van**]

A.A.Z "краток" как всегда!!!

[RayShade]

Автор топика, если ты пишешь программу дефрагментации, то как то смешно слышать вопрос о том, как выключить комп.

Если ты просто хочешь зашедулить виндовый дефраг - так зашедуль его и поставь в шедулере галку чтоб комп отрубился, как задача отработает.



Да, и еще - в вопросе вашем ен было ничего скзано ни про 6 часов ни про дефраг. Так что нечего возмущаться, что нет понимания. Какой вопрос такой и ответ.

[CyberYen]

А почему бы не сделать отдельно 2 проги: дефраг и выключатель.
Первая дефрагментирует, а вторую просто занести в список заданий Windows?

[A.A.Z.]

A.A.Z "краток" как всегда!!!

Ты знаешь способ отрубить NT кодом короче?

[mefestofele]

Спасибо всем но:
Крадкий код A.A.Z.'а несработал
а команда Shell ("Shutdown -s") выводит на экран чёрный экран с надписью
It is now safe to turn off your computer
А у меня WinXP-комп вырубается автоматически (без нажатия квалиши)
Комп можно вырубить комбинацией клавиш на клаве
Прадо яя не знаю кок нажимать (програмно) кнобки "Пуск" и стрелку вверх
A.A.Z. объснял как нажать кнобку "Enter" но про остальные кнобки нет
Может посоветуйте где взять набор команд ,изхадящих от клавы.

_________________
Да поможет тебе F1, Да сохранит тебя F2. Во имяя ALT'a, SHIFT'a и свяятого DEL'a, ESC.

[Шурик]

Это для ХР:

Код: Выделить всё

Shell "ShutDown -f -s"


только не пугайтесь(это я для тех, кто не знает что это системное окно) чере 20 секунд он сам вырубица....,

а это для 98 и МЕ:

Код: Выделить всё

Shell "rundll32 shell32,SHExitWindowsEx4"    'принудительно закрывает все программы
Shell "rundll32 shell32,SHExitWindowsEx8"    'выключение


[Шурик]

На счет 6 часов:
добавь таймер и установи интервал 60000 - это ровно 1 минута

Код: Выделить всё

Private Sub Timer1_Timer()
    tm = tm + 1                    'увеличение на 1 минуту
    If tm = 360 Then ....        'а здесь действие на выключение компа
End Sub


[mefestofele]

Cпасибо Z-zzz но результат точно такойже как и с командой Shell ("Shutdown -s") (Для полного выключения компа необходимо нажать кнобку Power)
Хотя при выключения компьютер через пуск этого не требуется
А про работу с таймером я и сам знаю

_________________
Да поможет тебе F1, Да сохранит тебя F2. Во имяя ALT'a, SHIFT'a и свяятого DEL'a, ESC.

[Шурик]

Ну не знаю, у меня все вырубается на раз-два, проверял на 3 компах. Посмотри в настройках питания.... может там ченить найдешь..