получить HTMLcod

[VLADosik]

как можно получить хтмл код старницы!?

Код: Выделить всё

Inet1.Execute "http://www.pnz.ru/", ""
Do While Inet1.StillExecuting
DoEvents
Loop
htmlcod = Inet1.GetChunk(0)
a = FreeFile
Open "c:\1.txt" For Append As d
Print #a, htmlcod 
Close #a


Мне надо сохранить весь хтмл код в фале, но он сохраняет малую часть, точнее получает не весь хтмл код... как сделать чтоб он получал весь код? говорят лучше получать кусками... как ето сделать?

[lister]

1) Залезь в FAQ: http://bbs.vbstreets.ru/viewtopic.php?t=7723
(C этого и надо начинать)

2) например, используй Winsock control

3) или wininet:

Код: Выделить всё

Option Explicit


Private Const INTERNET_OPEN_TYPE_DIRECT As Long = 1
Private Const INTERNET_OPEN_TYPE_PRECONFIG As Long = 0
Private Const INTERNET_OPEN_TYPE_PROXY As Long = 3
Private Const INTERNET_FLAG_RELOAD As Long = &H80000000

Private Const scUserAgent = "VB Project"

Private Declare Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" ( _
   ByVal lpszAgent As String, _
   ByVal dwAccessType As Long, _
   ByVal lpszProxy As String, _
   ByVal lpszProxyBypass As String, _
   ByVal dwFlags As Long) As Long

Private Declare Function InternetOpenUrl Lib "wininet.dll" Alias "InternetOpenUrlA" ( _
   ByVal hInternet As Long, _
   ByVal lpszUrl As String, _
   ByVal lpszHeaders As String, _
   ByVal dwHeadersLength As Long, _
   ByVal dwFlags As Long, _
   ByRef dwContext As Long) As Long

Private Declare Function InternetCloseHandle Lib "wininet.dll" ( _
   ByRef hInternet As Long) As Boolean

Private Declare Function InternetReadFile Lib "wininet.dll" ( _
   ByVal hFile As Long, _
   ByVal sBuffer As String, _
   ByVal dwNumberOfBytesToRead As Long, _
   ByRef lpdwNumberOfBytesRead As Long) As Integer

Public Function OpenUrl(ByVal sUrl As String) As String
  Dim hOpen As Long
  Dim hOpenUrl As Long
  Dim bDoLoop As Boolean
  Dim bRetval As Boolean
  Dim sReadBuffer As String * 2048
  Dim lNumberOfBytesRead As Long
  Dim sBuffer As String
 
  hOpen = InternetOpen( _
    scUserAgent, _
    INTERNET_OPEN_TYPE_PRECONFIG, _
    vbNullString, _
    vbNullString, _
    0 _
  )
 
  hOpenUrl = InternetOpenUrl( _
    hOpen, _
    sUrl, _
    vbNullString, _
    0, _
    INTERNET_FLAG_RELOAD, _
    0 _
  )
 
  bDoLoop = True
 
  While bDoLoop
    sReadBuffer = vbNullString

    DoEvents
   
    bRetval = InternetReadFile( _
      hOpenUrl, _
      sReadBuffer, _
      Len(sReadBuffer), _
      lNumberOfBytesRead _
    )
   
    sBuffer = sBuffer & Left$(sReadBuffer, lNumberOfBytesRead)
   
    If Not CBool(lNumberOfBytesRead) Then bDoLoop = False
   
  Wend
 
  If hOpenUrl <> 0 Then InternetCloseHandle (hOpenUrl)
 
  If hOpen <> 0 Then InternetCloseHandle (hOpen)
 
  OpenUrl = sBuffer
 
End Function

[tyomitch]

А ещё есть качалка в кирпичах.

[Raz0r]

А еще есть Marby HTTPX Control. Просто пишешь:
HttpX1.Get "127.0.0.1" и получаешь исходный код страницы

[Мамонт]

но он сохраняет малую часть, точнее получает не весь хтмл код... как сделать чтоб он получал весь код?

Этот глючный инетконтрол некачает доканца! Лучше использовать winsock. Это факт!

[Мамонт]

Raz0r

А непроще ещё 2 строки добавить и не грузиться со всякими контролами?

[Debugger]

А можно исходник ЗАЛИТИЯ файла через винсок?

[Мамонт]

Диржы!

[tyomitch]

Format, научись читать!

[Мамонт]

Ой! Чёрт! Сори!

[Мамонт]

Ну так тема то называется получить HTMLcod вот я и прочитал неправельно! Устал просто!