Диалог выбора папки

[Gigahard]

В XP и 2k при создани ярлыка, есть диалог "Обзор папок" с помощью которого можно выбрать необходимый объект. Стандартный ли это диалог и как его вызвать? Пока сделал аналог выбра папки из контролов DriveListBox и DirListBox, но все это выглядит по старомодному и имхо не особо удобно в плане навигации. Вот и вопрос, как вызвать этот самый виндовый диалог выбора папки? Или он не стандартный и его надо делать ручками? Просто не хотелось бы изобретать велосипед, если таковой уже есть:).

[Amed]

Код: Выделить всё

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo

    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:\", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If

    MsgBox sPath
End Sub

[Gigahard]

Огромнейшее спасибо! А этот диалог применим к win 9x и Me или только на NT системах существует, а то я что то уже забыл, было ли такое на 98х...

[Amed]

Как пишет api-guide,

Requires Windows NT 4.0 or later; Requires Windows 95 or later

[Gigahard]

Еще раз спасибо
Возник еще один вопрос... Вот контрол DriveListBox позволяет отслеживать готовность дисковода. Как такое реализовать на базе этого диалога?

[Gigahard]

Странно, в качестве флага, вместо BIF_RETURNONLYFSDIRS указал BIF_NEWDIALOGSTYLE, для того чтобы появилась возможность создания папки, но диалог как то подглючивает, он подмаргивает и подтормаживает. Такое ощущение, что рефрешится. Может что еще надо для BIF_NEWDIALOGSTYLE указывать?


----------------

В скомпилированом варианте тормоза пропали. Видимо глюк дебагера.

--------------

Все, со всеми вопросами разобрался. Темку можно закрывать.