Form_Layout или Как перехватить движение формы

[X-BOND]

В VBA у формы есть событие UserForm_Layout, которое помогало таскать за главной формой другие формы. В VB такого, к сожалению, нет. Как можно перехватить событие движения формы по экрану не используя GetCursorPos, таймеры и циклы?
Может быть истина где-то рядом...
Спасибо за ответы.

[MEMBER]

В модуль:

Код: Выделить всё

Declare Function SetWindowLong Lib "user32" Alias _
                 "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
                 As Long, ByVal dwNewLong As Long) As Long
               
Declare Function CallWindowProc Lib "user32" Alias _
                 "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
                 ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam _
                 As Long, ByVal lParam As Long) As Long
                   

Public Const GWL_WNDPROC = -4
Public Const WM_MOVE = &H3
Public gWH As Long
Public OldWndProc As Long
'------------------------------
Function WindowProc(ByVal hwnd As Long, ByVal Msg As Long, ByVal _
                    wParam As Long, ByVal lParam As Long) As Long
    Dim lReturn As Long
    lReturn = CallWindowProc(OldWndProc, hwnd, Msg, wParam, lParam)
    Select Case Msg 'проверяем сообщения
        Case WM_MOVE 'если нужное нам, то выполняем некоторые действия
         MsgBox ("Поехали!!!")
    End Select
    WindowProc = lReturn 'вернем значение функции
End Function


В форму:

Код: Выделить всё

Private Sub Form_Load()
    gWH = Me.hwnd 'дескриптор нашего окна
    OldWndProc = SetWindowLong(gWH, GWL_WNDPROC, AddressOf WindowProc)
End Sub
'------------------------------
Private Sub Form_Unload(Cancel As Integer)
    SetWindowLong gWH, GWL_WNDPROC, OldWndProc
End Sub