Быстрая работа со строками

[|kerish|]

Нужен самый максимальный по скорости метод получения определенной строки из текста.
Слышал про библиотеку для быстрой работы с текстом.
Посоветуйте самый реактивный метод.

[Джеффи]

Нужен самый максимальный по скорости метод получения определенной строки из текста.
Слышал про библиотеку для быстрой работы с текстом.
Посоветуйте самый реактивный метод.

А чем не устраивает Split?

[Джеффи]

Или попробуй сочитание InStr с Mid...

[|kerish|]

Джеффи Пробовал сочетания Mid и Instr. Жутко
Есть следующая функция:

Код: Выделить всё

Public Function ReadLine(Text As String, NumberLine As Long) As String
Dim Str As String, Ln As String
Dim i As Long
Dim CurLine As Long
Dim CurSym As String
CurLine = 1
Str = Text
On Error Resume Next
For i = 1 To Len(Str)
CurSym = Mid(Str, i, 1)
If CurLine = NumberLine Then
  If (Asc(CurSym) <> 10) And (Asc(CurSym) <> 13) Then Ln = Ln & CurSym
End If
If Asc(CurSym) = 13 Then CurLine = CurLine + 1
If CurLine > NumberLine Then GoTo lblexit
Next i
lblexit:
ReadLine = Ln
End Function


Это самый быстрый вариант из того, что я имею.
Но он меня не устраивает, так как он самый быстрый из медленных.
Может поможете его оптимизировать или подскажите идею нового варианта.
Связка Mid и Instr получается в разы медленнее этого варианта.

[tyomitch]

А чем не устраивает Split?

Так чем же?

[sash]

Попробуй так, если я правильно понял

Код: Выделить всё

Public Function ReadLine(Text As String, NumberLine As Long) As String
    Dim sTemp() As String
   
    On Local Error Resume Next
   
    ReadLine = ""
       
    sTemp = Split(Text, vbCrLf)
   
    If (UBound(sTemp()) + 1) < NumberLine Then
        Exit Function
    Else
        ReadLine = sTemp(NumberLine - 1)
    End If
   
End Function


[|kerish|]

sash спасибо это лучше.
А ещё быстрее никак нельзя?
Например через какую-нибудь библиотеку из C++?

[sash]

А чем так долго?? Скормил функции String содержащии 40000 строк, так она мгновено выдал 39 509 строку.Наврядли на Си намного быстрее получиться.

Вот так побыстрее будет работать, особенно если много строк а нужно начальную.

Код: Выделить всё

Public Function ReadLine(Text As String, NumberLine As Long) As String
    Dim sTemp() As String
   
    On Local Error Resume Next
   
    ReadLine = ""
       
    sTemp = Split(Text, vbCrLf, NumberLine + 1) 'Изменение
   
    If (UBound(sTemp()) + 1) < NumberLine Then
        Exit Function
    Else
        ReadLine = sTemp(NumberLine - 1)
    End If
   
End Function

[|kerish|]

Огромнейшее спасибо!

[sash]

Так еще на пару тактов

Код: Выделить всё

Public Function ReadLine(Text As String, NumberLine As Long) As String
    Dim sTemp() As String
   
    On Local Error Resume Next
   
    ReadLine = ""
       
    sTemp = Split(Text, vbCrLf, NumberLine + 1)
   
    ReadLine = sTemp(NumberLine - 1)
   
End Function


[sash]

Окончательный вариант, дальше некуда

Код: Выделить всё


Public Function ReadLine(Text As String, NumberLine As Long) As String
   
    On Local Error Resume Next
   
    ReadLine = Split(Text, vbCrLf, NumberLine + 1)(NumberLine - 1)
   
End Function


[GSerg]

Ну почему же

Код: Выделить всё

Public Function ReadLine(Text As String, ByVal NumberLine As Long) As String
   
    On Local Error Resume Next
   
    ReadLine = Split(Text, vbCrLf, NumberLine + 1)(NumberLine - 1)
   
End Function

Так ещё быстрее ввиду отсутствия необходимости в одном дереференсе

[alibek]

А в чем отличие On Error и On Local Error в VB6?

[Antonariy]

Загляни сюда - http://www.xbeat.net/vbspeed/index.htm
Сайт посвящен более производительным альтернативам стандартных вбшных функций.