TrayIcon

[lilak]

Никак не получается загнать в системный tray иконку.
В API Guide подыскал подходящую функцию- Shell_NotifyIcon,
но как её заставить практически работать?Компилятор всё время ругается. Может быть у кого-то есть работающий пример с этой функцией?Плииз!

[GSerg]

Ты знаешь, уже проще найти человека, у которого нет работающего примера shell_notifyicon...

Если есть api-guide, то есть и пример. Copy. Paste. F5. Enjoy.

[lilak]

Если есть api-guide, то есть и пример. Copy. Paste. F5. Enjoy.

Конечно, так и делаю. Только вот с Enjoy-не получается -ругается компилятор. Потому и пишу. Если есть реальный пример- помоги, пожалуйста.

[GSerg]

Нет уж, разберёмся...

Что именно говорит компилятор?

[Серый]

Вот тут вопрос о трее возник:
Как узнать какие значки (программы) "засунуты" в трей?

[tyomitch]

Ну дают...
Один из многочисленных примеров тут: http://mastershome.net.ru/vbfaq/d02.htm

Работающий не везде пример получения иконок из трея (от Оловянникова) у меня есть, но я так и не смог заставить его работать в своей Win2000. В Win98 и WinXP, по словам Оловянникова работает. Кинуть сюда?

[xolod]

Кидай, интересно, почему он у тебя не заработал.. XP и 2k api'шками не сильно отличаются, да и принципы почти одни и те же

[tyomitch]

Ок... Проверьте плз кто где может, а то мне уже самому интересно

[lilak]

Нет уж, разберёмся...

Что именно говорит компилятор?

Прежде хочу показать, что говорит Апи Гид:
Код из примера:
Private Type NOTIFYICONDATA
cbSize As Long
hWnd As Long
uId As Long
uFlags As Long
ucallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type

Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4

Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_RBUTTONUP = &H205

Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
Dim TrayI As NOTIFYICONDATA
Private Sub Form_Load()
TrayI.cbSize = Len(TrayI)
'Set the window's handle (this will be used to hook the specified window)
TrayI.hWnd = pichook.hWnd
'Application-defined identifier of the taskbar icon
TrayI.uId = 1&
'Set the flags
TrayI.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
'Set the callback message
TrayI.ucallbackMessage = WM_LBUTTONDOWN
'Set the picture (must be an icon!)
TrayI.hIcon = imgIcon(2).Picture
'Set the tooltiptext
TrayI.szTip = "Recent" & Chr$(0)
'Create the icon
Shell_NotifyIcon NIM_ADD, TrayI

Me.Hide
End Sub
Private Sub Form_Unload(Cancel As Integer)
'remove the icon
TrayI.cbSize = Len(TrayI)
TrayI.hWnd = pichook.hWnd
TrayI.uId = 1&
Shell_NotifyIcon NIM_DELETE, TrayI
End
End Sub
На что компилятор плюётся

Sub or Function not defined

и выделяет строку TrayI.hIcon = imgIcon(2).Picture

[GSerg]

Нет чтоб разобраться?

Ну помести на форму пикчербокс, загони в него иконку, и укажи там его имя вместо imgIcon(2).

[Ruslan Demidow]

Нет чтоб разобраться?

Ну помести на форму пикчербокс, загони в него иконку, и укажи там его имя вместо imgIcon(2).

Или просто

Код: Выделить всё

TrayI.hIcon =Me.Icon


[lilak]

GSerg писал(а):
Нет чтоб разобраться?

Ну помести на форму пикчербокс, загони в него иконку, и укажи там его имя вместо imgIcon(2).
Или просто
Код:

TrayI.hIcon =Me.Icon

Делал и по-GSerg:TrayI.hIcon =PictureBox-name.Picture

и по-Ruslan Demidow: TrayI.hIcon =Me.Icon

и(что то же самое) :TrayI.hIcon =Form-name.Icon


Ругается! Но уже по-другому:

Run-time error '404'
Object required

и при debug выделяет строку:
TrayI.hWnd = pichook.hWnd

[GSerg]

Ничё человек не хочет разбираться...
TrayI.hWnd = me.hWnd

[lilak]

Ничё человек не хочет разбираться...
TrayI.hWnd = me.hWnd

Спасибо,GSerg, за твоё терпение и за желание помочь.
Ты мне действительно помог и многому научил.
Хотя в данном конкретном эпизоде кода есть решение и проще-данную строчку TrayI.hWnd = me.hWnd можно просто убрать.
Но спасибо- иконка стала появляться -таки в трэйе, хотя появилась и проблема: при наведении на иконку в трэйе мышкой- иконка сразу пропадает, а хотелось бы сделать поп-меню. С поп-меню я буду ещё возиться, а вот почему пропадает сама иконка?

[tyomitch]

Именно потому и пропадает, что нельзя эту строчку убирать

[lilak]

Спасибо,Tyomitch, с благодарностью принимаю все советы и рекомендации. А сейчас пару слов о твоей программе NewTray.rar
Попробовал её в win XP
После запуска программы меня тут же обругали:

Windows Explorer has encountered a problem and needs to close.

А после того как я закрыл это сообщение, поднялась форма с таблицей: Who lives in my systemtray?

В таблице 5 колонок
-1) icon and Executable
- 2) hwind
- 3) uID
- 4) Callback.msg
- 5) State

По горизонтали же были 13 одинаковые строчки, заполненные соответственно колонкам так:
-1) c:\windows\explorer.exe
-2) 197286
-3) -4
-4) 0(0x0)

-5) Hidden


О программах, иконки которых реально находились в трее сказано ничего не было.
_____________________________________________________________
Ночь хороша тем, что после неё приходит рассвет-

[tyomitch]

А сейчас пару слов о твоей программе NewTray.rar

Она не моя, она оловянниковская. У меня она тоже не работает

Ещё, плз проверьте её кто-нибудь на Win98, а?

[xolod]

В XP падает при попытке послать сообщение трею TB_GETBUTTONINFOA, т.е. при попытке получить информацию о конкретном значке.. Но самое интересное не это, перезагружаюсь в savemode - все работет, даже меню определеят
"Ничего не понимаю" (c)

[tyomitch]

Ещё, плз проверьте её кто-нибудь на Win98, а?

Вот, я сейчас проверил. Не работает (
Позор на седины Оловянникова.

[GSerg]

Он, видимо, не виноват...
Я тоже долго пытался слать этому тулбару всякие правильные мессаги, и ничё не получал хорошего.

[Memfivosfey]

Мож это поможет?
Вытаскивай RARом добавляй объектом к своей форме и работай...

[Memfivosfey]

Sorry! Комп глюконуло...

[Memfivosfey]

Sorry! Комп глюконуло...

[tyomitch]

Memfivosfey, ты б хоть топик прочитал, прежде чем одно и то же трижды постить.

[Александр80]

Возможно я что-то не допонял... Но если интересно, то можно загнать иконку в TRAY и так... Это работает, у меня проблем не вызывало...

Добавьте на форму PictureBox и введите следующий код
Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias _
"Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4

Private Const WM_MOUSEMOVE = &H200
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_LBUTTONUP = &H202
Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_RBUTTONDOWN = &H204
Private Const WM_RBUTTONUP = &H205
Private Const WM_RBUTTONDBLCLK = &H206
Private Const WM_MBUTTONDOWN = &H207
Private Const WM_MBUTTONUP = &H208
Private Const WM_MBUTTONDBLCLK = &H209

Private Type NOTIFYICONDATA
cbSize As Long
hWnd As Long
uId As Long
uFlags As Long
ucallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type

Dim IconData As NOTIFYICONDATA

Private Sub Form_Load()
Picture1.Visible = False
IconData.cbSize = Len(IconData)
' События, связанные с иконкой будут отображаться в
' Picture1_MouseMove
IconData.hWnd = Picture1.hWnd
IconData.ucallbackMessage = WM_MOUSEMOVE
' Изображение иконки
IconData.hIcon = Form1.Icon
IconData.uId = 1&
IconData.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
' Текст подсказки
IconData.szTip = "Пример помещения иконки в трей" & Chr$(0)
' Добавляем иконку в трей
Shell_NotifyIcon NIM_ADD, IconData
End Sub

Private Sub Form_Unload(Cancel As Integer)
' Удаляем иконку из трея
IconData.cbSize = Len(IconData)
IconData.hWnd = Picture1.hWnd
IconData.uId = 1&
Shell_NotifyIcon NIM_DELETE, IconData
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, _
X As Single, Y As Single)
' События, связанные с иконкой можно узнать по координате X
If X / Screen.TwipsPerPixelX = WM_LBUTTONDOWN Then _
MsgBox "Нажата левая кнопка мыши"
End Sub

[tyomitch]

Александр80, не допонял. Обсуждалась не на тысячу раз уже пережёванная тема "как засунуть иконку в трей", а противоположная - "как узнать, что туда уже засунуто".