Определение пути папки

[Nazar]

Делаю программу, которая должна обработать все текстовые файлы, находящиеся в конкретной папке. Можно ли с помощью элемента управления CommonDialog.ShowOpen получить путь к папке? Путь к конкретному файлу ненужен, только к папке.

[Amed]

У меня сразу не получилось выбирать папки, а разбираться неохота. Поэтому лучше использовать SHBrowseForFolder:

Код: Выделить всё

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo

    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:\", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If

    MsgBox sPath
End Sub


[Tin]

а почему бы просто объект Dir не поюзать, господа? Дёшево и сердито

[Ruslan Demidow]

а почему бы просто объект Dir не поюзать, господа? Дёшево и сердито

А папку ты как пользователю предложишь выбрать? Вот про это и топик...

[tyomitch]

Ruslan, речь идёт не а функции Dir, а о контроле DirBox...

[Ruslan Demidow]

Ruslan, речь идёт не а функции Dir, а о контроле DirBox...

Ага. Теперь понял.

[Amed]

Можно и DirListBox, конечно. Но это сердито и некрасиво %)

[Tin]

ну а чем тогда комдлг лучше? чем он красивее?

[SHURUP]

Как по мне, то идеально - текстовое поле, а рядом кнопка "Обзор…" - чтоб можно было или текст ввести, или по SHBrowseForFolder - выбрать.
Токо вот желательно, чтоб при написании адресса в текстбоксе - предлагалися возможные существующие папки.

[Tin]

на вкус и цвет, как говориться..

[tyomitch]

Токо вот желательно, чтоб при написании адресса в текстбоксе - предлагалися возможные существующие папки.

Вот пример автоподстановки:

Код: Выделить всё

'Code by Lъcio Chaves (luciochaves@bol.com.br)
'This program needs a textbox ('Text1') on a form
Private Const SHACF_AUTOAPPEND_FORCE_OFF = &H80000000
Private Const SHACF_AUTOAPPEND_FORCE_ON = &H40000000
Private Const SHACF_AUTOSUGGEST_FORCE_OFF = &H20000000
Private Const SHACF_AUTOSUGGEST_FORCE_ON = &H10000000
Private Const SHACF_DEFAULT = &H0
Private Const SHACF_FILESYSTEM = &H1
Private Const SHACF_URLHISTORY = &H2
Private Const SHACF_URLMRU = &H4
Private Const SHACF_USETAB = &H8
Private Const SHACF_URLALL = (SHACF_URLHISTORY Or SHACF_URLMRU)
Private Declare Sub SHAutoComplete Lib "shlwapi.dll" (ByVal hwndEdit As Long, ByVal dwFlags As Long)
Private Sub Form_Load()
    SHAutoComplete Text1.hWnd, SHACF_DEFAULT
End Sub


[SHURUP]

2tyomitch: именно то! Плюс кнопка "броуз" из поста Amed-a и будет - ВэрриГуд!