Как передать массив элементов управления в процедуру?

[AndreyG_80]

Всем доброго времени суток.
Что-то у меня не получаеться передать массив элементов управления в процедуру.
Вот пример:
У меня есть массив элементов управления Label. Я хочу его обработать в модуле, но ни как не могу передать в процедуру весь массив.
Обработка события MouseMove для контролов массива

Код: Выделить всё

Private Sub Label1_MouseMove(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
    MouseMove Label1 , Index
End Sub

Процедура находящаяся в модуле

Код: Выделить всё

Public Sub MouseMove(Control As Label, Index As Integer)
    For i = 0 To Control.Count - 1
        Control.Item(i).BorderStyle = vbBSNone
    Next i
        Control.Item(Index).BorderStyle = vbFixedSingle
End Sub

Подскажите пожалуста, в каком месте кода я торможу, при обьявлении "Control As Label" или при передаче параметра в прочедуру?

Заранее длагодарен за помощь

[GSerg]

Код: Выделить всё

Public Sub MouseMove(ByVal Control As Object, ByVal Index As Integer)
  Dim i As Long
   
  For i = 0 To Control.Count - 1
    Control(i).BorderStyle = vbBSNone
  Next

  Control(Index).BorderStyle = vbFixedSingle
end sub

[AndreyG_80]

Большое спасибо,
все оказалось так просто, аж стыдно, что я так затупил

[Andrey Fedorov]

И чуть по другому:

Код: Выделить всё

Private Sub lb_MouseMove(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
    MouseMove lb, Index
End Sub

Public Sub MouseMove(ml As Object, Index As Integer)
    Dim l As Label
    For Each l In ml
        l.BorderStyle = IIf(l.Index = Index, vbFixedSingle, vbBSNone)
    Next l
End Sub

Ну и совсем по рабоче-крестьянски, без функции MouseMove:

Код: Выделить всё

Private Sub lb_MouseMove(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim l As Label
    For Each l In lb
        l.BorderStyle = IIf(l.Index = Index, vbFixedSingle, vbBSNone)
    Next l
End Sub

[Хакер]

А можно ещё компактнее и быстрее:

Код: Выделить всё

Private Sub lb_MouseMove(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
    For i = lb.LBound To lb.UBound
       lb(i).BorderStyle=Abs(i=Index):Next i
End Sub

[ANDLL]

А можно ещё компактнее и быстрее:

И неправильнее...
Следует писать:

Код: Выделить всё

For each i in lb
       i.BorderStyle=Abs(i.index=Index)
Next


[GSerg]

Abs(i.index=Index)

Это называется "я полагаюсь на числовое значение констант", что, в целом, равнозначно "Да какой я, нафиг, программист, так, мимо проходил".

[Хакер]

Знешь что GSerg. если у тебя есть желание наехать на кого нибудь, то для этого есть специальные форумы.

Что? Ты хочешь сказать, значение этой константы изменится? Когда? В следующей версии? Которой уже никогда не будет?