Вопрос по перекрестным ссылкам

[alibek]

Вот с таким вопросом застрял

Есть объект Document.
У него есть иерархическая коллекция Tags, в которой хранятся элементы Tag, каждый из которых может иметь свою дочернюю коллекцию Tags (в Document хранится иерархическая коллекция HTML-тэгов).

Вот пример заполнения документа:

Код: Выделить всё

Dim doc As New Document
With doc.Tags
  .Add "DOCTYPE", True
  With .Add("HTML").Childs
    With .Add("HEAD").Childs
      .Add "TITLE"
      .Add "BASE"
      .Add "META"
    End With
    With .Add("BODY").Childs
      .Add "P"
      With .Add("TABLE").Childs
        With .Add("TR").Childs
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
        End With
      End With
      .Add "IMG"
      With .Add("DIV").Childs
        .Add "IMG"
      End With
    End With
  End With
End With


Допустим, есть такой код:

Код: Выделить всё

Dim T As Tag
With tvwTest.Nodes
  .Clear
  For Each T In doc.Tags
    Nodes.Add Text:=T.Name
  Next T
End With
doc.CleanUp
Set doc = Nothing

В doc.CleanUp выполняется очистка данных (обнуляются ссылки и т.п.).
Так вот, после Set doc = Nothing в процедуре имеется одна незакрытая ссылка на Tags (если конкретно, то на doc.Tags). В doc.CleanUp эта ссылка обнуляется, значит есть еще одна объектная переменная, ссылающаяся на нее.

Если убрать For Each, то лишней ссылки не остается.

Если For Each оформить так:

Код: Выделить всё

Dim C As Tags
Set C = doc.Tags
For Each T In C
  ...
Next T
Set C = Nothing

то лишней ссылки также не остается.

Или если вынести For Each в отдельную процедуру

Код: Выделить всё

Private Sub test(doc As Document, Nodes As Nodes)
Dim T As Tag
For Each T In doc.Tags
  Nodes.Add Text:=T.Name
Next T
End Sub


и вместо For Each вызывать Call test, то лишней ссылки также не остается.

Больше всего похоже на то, что For Each создает временную переменную, но не очищает ее, когда цикл отрабатывает.


Вопрос простой: что делать?

[Ennor]

Впервые о таком слышу. Никогда раньше не сталкивался.

А в каком месте у тебя сейчас этот код, если его вынос в отдельный суб решает проблему?

[GSerg]

Я тоже, и мы не смогли найти решение в привате

Если перечислитель коллекции находится в той же процедуре, что и создание/уничтожение объекта, то объект не уничтожается - так, словно на момент вызова CleanUp существует та самая временная ссылка, созданная перечислителем, которая по идее должна отрелизиться в момент выхода из цикла.

[alibek]

Сейчас код в основном месте
Просто хотелось бы данный класс сделать максимально автономным и удобным для использования. Перебор в отдельной процедуре или создание временной переменной для коллекции в крайнем случае тоже пойдет, но "на экспорт" так не делают
В принципе, даже CleanUp на "экспорт" не делается, но ничего более подходящего (кроме выноса во внешний ActiveX) не приходит в голову.

[Vi]

Скорее всего проблема в определении через As New Document. Цикл For Each нормально отрабатывает и не имеет побочных эффектов.

[alibek]

Имел тайное желание, чтобы появился Vi, желание исполнилось
Что может обуславливать такое поведение?
Код класса Document:

Код: Выделить всё

Option Explicit

Private varReadOnly As Boolean
Private varFlatMode As Boolean

Private objHTMLStore As TextStore
Private objTags As Tags

Public Property Get Tags() As Tags
Set Tags = objTags
End Property

Public Property Get HTMLStore() As TextStore
Set HTMLStore = objHTMLStore
End Property

Public Sub CleanUp()
Dispose
End Sub

Friend Sub Create()
Set objTags = New Tags
objTags.Create Nothing, Me, objHTMLStore
objTags.SetReadOnly varReadOnly
objTags.SetFlatMode varFlatMode
End Sub

Friend Sub Dispose()
If Not objTags Is Nothing Then
  objTags.Dispose
  Set objTags = Nothing
End If
End Sub

Private Sub Class_Initialize()
Print #1, "Document + :: " & ObjPtr(Me)
varReadOnly = True
varFlatMode = True
Set objHTMLStore = New TextStore
Create
End Sub

Private Sub Class_Terminate()
Print #1, "Document - :: " & ObjPtr(Me)
Set objHTMLStore = Nothing
End Sub


Вроде бы никакого криминала нет.

[alibek]

Такая инициализация:

Код: Выделить всё

Dim doc As Document
Set doc = New Document


поведение не меняет. Т.е. один инстанс Tags (doc.Tags) висит как и раньше, пока процедура не завершит работу.

[alibek]

Вот еще что выяснил.
Если For Each не используется, то объекты закрываются в таком порядке:
Tags (doc.Tags)
Document (doc)
TextStore (doc.TextStore)
Если цикл For Each используется, то порядок закрытия такой:
Document (doc)
TextStore (doc.TextStore)
<конец процедуры>
Tags (doc.Tags)

[Vi]

А не мог бы ты, если не секрет, выложить коды всех классов и точную проблемную процедуру? Если секрет, то можно в приватный мейл с гарантией неразглашения.

[alibek]

Ну поскольку я все-равно собирался выложить исходники, когда проект будет закончен, то не секрет

Дополнительно необходим код:

Код: Выделить всё

Public Const vbSpace As String = " ", vbSpace2 As String = "  "
Public Const vbSkip As String = "-"
Public Const vbEmptyDate As Date = 0


Проблемная процедура:

Код: Выделить всё

Open "C:\debug.txt" For Output As #1
Dim doc As Document, T As Tag
Set doc = New Document
With doc.Tags
  .Add "DOCTYPE", True
  With .Add("HTML").Childs
    With .Add("HEAD").Childs
      .Add "TITLE"
      .Add "BASE"
      .Add "META"
    End With
    With .Add("BODY").Childs
      .Add "P"
      With .Add("TABLE").Childs
        With .Add("TR").Childs
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
        End With
        With .Add("TR").Childs
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
        End With
        With .Add("TR").Childs
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
          With .Add("TD").Childs
            .Add "P"
            .Add "P"
            .Add "P"
          End With
        End With
      End With
      .Add "IMG"
      With .Add("DIV").Childs
        .Add "IMG"
      End With
    End With
  End With
End With
For Each T In doc.Tags
  Debug.Print T.Name
Next T
doc.CleanUp
Set doc = Nothing
Print #1, "***"
'Close #1


[Vi]

Я тоже присоединяюсь к вышеприведенным соображениям и беру назад свои слова о том, что "Цикл For Each ... не имеет побочных эффектов". Как оказывается, имеет. Видимо, реализацию For Each писали студенты (индийские ).

Причем вложенные For Each (например, For Each T In doc.Tags: For Each v In T.Childs ... ) приводят к удержанию последней коллекции во вложенном цикле и не увеличивают общее количество удерживаемых. Поэтому соответствие переменных и циклов 1:1. По-видимому, это последняя полезная информация.

***EDIT*** Это - задействование переменной - относится к сложным вычислениям объекта (например, "doc.Tags" и т.п.), у которого берут коллекцию. Видимо, были случаи, когда разрушение объекта приводило к разрушению коллекции. Поэтому и сохраняют. ***EDIT***

Однако такое поведение не приводит к сколь значимым проблемам, видимым конечным пользователем, и может быть отброшено из расмотрения как несущественное. Таково мое резюме.



vbskb_bug vbskb_collection

[alibek]

Сенкс
Ну что ж, буду кодить с учетом этого.

[alibek]

Ура!

В классе Document я добавил новую проперть:

Код: Выделить всё

Public Property Get NewEnum() As IUnknown
Set NewEnum = objTags.NewEnum
End Property


Определил эту проперть, как скрытую (Hidden) и перечислитель (DispID = -4).

С клиентской стороны теперь тэги перебираются так:

Код: Выделить всё

For Each T In doc
  Debug.Print T.Name
Next T

Все работает.


Сенкс tyomitch-у

[Ennor]

Ты этого не знал?Я идиот! Убейте меня, кто-нибудь!

[alibek]

Не догадался

[Vi]

А попробуй эквивалентное "For Each T In doc.Tags.Document"? И потом как ты запретишь клиенту использовать более красивое и логичное "For Each T In doc.Tags"? И к чему это может привести (именно у клиента)?

[tyomitch]

А попробуй эквивалентное "For Each T In doc.Tags.Document"? И потом как ты запретишь клиенту использовать более красивое и логичное "For Each T In doc.Tags"? И к чему это может привести (именно у клиента)?

По крайней мере, теперь сделать неправильно стало сложнее, чем сделать правильно