хочу написать!!!

[TX]

дали задание написать прогу, которая бы -
говорила бы с тобой - типа - выбираешь раздел и начинаешь отгадывать то что в этом разделе есть водными вопросами
пример раздел "механика" ->
ты задаешь вопрос - колеса есть - машина говорит "да"(и у нее в базе данных сразу строитса дерево - допустим колеса есть у всей техники в этом разделе)
ты задаешь следующий вопрос - дуло есть - машина говорит "да"(сразу у нее отсееваетса половина техники, которые не имеют дуло) ... и так вот задавая вопросы ты подходишь к концу и комп показывает на кого ты пришел(какую технику ты отгадал)
+ комп может обучатса

какие могут быть предложения

[FaKk2]

Ну, в голову приходит банальный SELECT...

[alibek]

Банальный SELECT и не банальная, а хорошо структурированная база

[Ennor]

Ага, причем не на SQL, а на Prolog - оно попроще программить будет...

[tyomitch]

OMG, у меня исходник именно такой игры был в книге "Знакомьтесь, персональная ЭВМ Корвет". Ещё на том Бейсике, что с номерами строк...
Там было без базы, без SELECT-а и без Пролога...

(Там страниц 10 тетрадного формата, так что набивать не буду, а сканера у меня нету )

[ta_gena]

Чтобы железяка начала обучатса сдесь никаким SELECT'ом не обойдешся. Тут, наверно, надо WinAPI32 подключать где-нибудь сбоку.

[tyomitch]

ta_gena, ты неправ дважды
Во-первых, чтобы железяка начала обучаться, наряду c SELECT-ом нужен и INSERT
А во-вторых, API здесь как раз никаким боком.

[tyomitch]

Вот, написал за час угадывалку, персистирующую в реестр...

Это должен быть ActiveX EXE, Start Mode -> Standalone

Модуль:

Код: Выделить всё

Option Explicit
Dim Root As Question

Sub Main()
Dim c As Question, s As String, pb As PropertyBag, v As Variant
'Инициализация
v = GetSetting(App.Title, "Data", "Root")
If Len(v) Then
    Dim b() As Byte
    Set pb = New PropertyBag
    b = v
    pb.Contents = b
    Set Root = pb.ReadProperty("Root")
Else
    Set Root = New Question
    Root.Thing = "компьютер"
End If
'Основной цикл
Do
    MsgBox "Задумай предмет"
    Set c = Root
    Do
        If Len(c.Thing) Then
            If MsgBox("Это " & c.Thing & "?", vbYesNo) = vbYes Then
                MsgBox "Ура, ура!"
                GoTo ThingDone
            Else
                Exit Do
            End If
        Else
            If MsgBox("Это " & c.Text & "?", vbYesNo) = vbYes Then
                Set c = c.Yes
            Else
                Set c = c.No
            End If
        End If
    Loop
    s = InputBox("Что это за предмет?")
    Set c.No = New Question
    c.No.Thing = s
    Set c.Yes = New Question
    c.Yes.Thing = c.Thing
    c.Thing = vbNullString
    c.Text = InputBox("Чем " & c.Yes.Thing & " отличается от " & c.No.Thing & "?")
ThingDone:
    If MsgBox("Продолжить?", vbYesNo) = vbNo Then Exit Do
Loop
Set pb = New PropertyBag
pb.WriteProperty "Root", Root
SaveSetting App.Title, "Data", "Root", pb.Contents
End Sub


Класс Question: (Instancing -> 5 - MultiUse, Persistable -> 1 - Persistable)

Код: Выделить всё

Option Explicit

Public Yes As Question
Public No As Question
Public Text As String
Public Thing As String

Private Sub Class_ReadProperties(PropBag As PropertyBag)
If PropBag.ReadProperty("Type", "Leaf") = "Leaf" Then
    Thing = PropBag.ReadProperty("Thing")
Else
    Set Yes = PropBag.ReadProperty("Yes")
    Set No = PropBag.ReadProperty("No")
    Text = PropBag.ReadProperty("Text")
End If
End Sub

Private Sub Class_WriteProperties(PropBag As PropertyBag)
If Len(Thing) Then
    PropBag.WriteProperty "Type", "Leaf", "Leaf"
    PropBag.WriteProperty "Thing", Thing
Else
    PropBag.WriteProperty "Type", "Node", "Leaf"
    PropBag.WriteProperty "Yes", Yes
    PropBag.WriteProperty "No", No
    PropBag.WriteProperty "Text", Text
End If
End Sub


[TX]

ого - круто

[TX]

а как поклучить mysql ну чтобы окутда он брал готовые ответы