Получение информации из других приложений

[pronto]

Возникла простая, на первый взгляд, задача - считать текстовое значение текстбокса, который принадлежит другой проге. А?

[GB826]

Наверно в поиск пошлют...

[AndreyIl]

FindWindow
FindWindowEx

Посмотри пример на vb.kiev.ua

[Kostyan]

Я знаю 3 способа изымания текста из текстбокса.
Первый:

Код: Выделить всё

Public Function GetText1(ByVal hwnd As Long) As String
Dim l As Long, s As String, lc As Long, i As Long
GetText1 = ""
lc = SendMessageL(hwnd, EM_GETLINECOUNT, 0, 0) - 1
For i = 0 To lc
    l = SendMessageL(hwnd, EM_LINEINDEX, i, 0)
    l = SendMessageL(hwnd, EM_LINELENGTH, l, 0) + 1
    s = String$(l + 2, 0)
    Mid$(s, 1, 1) = Chr$(l And &HFF)
    Mid$(s, 2, 1) = Chr$(l \ &H100)
    l = SendMessageS(hwnd, EM_GETLINE, i, s)
    GetText1 = GetText1 & Left$(s, l) & IIf(lc = 0 Or lc = i, "", vbCrLf)
Next
End Function

Второй:

Код: Выделить всё

Public Function GetText2(ByVal hwnd As Long) As String
Dim l As Long, s As String
l = SendMessageL(hwnd, WM_GETTEXTLENGTH, 0, 0) + 1
s = String$(l, 0)
l = SendMessageS(hwnd, WM_GETTEXT, l, s)
GetText2 = Left$(s, l)
End Function

Третий:

Код: Выделить всё

Public Function GetText3(ByVal hwnd As Long) As String
Dim l As Long, s As String
l = GetWindowTextLength(hwnd) + 1
s = String$(l, 0)
l = GetWindowText(hwnd, s, l)
GetText3 = Left$(s, l)
End Function

2 и 3 практически идентичны, и применимы к любым окнам. А вот первый можно использовать ТОЛЬКО с текстбоксами.

P.S. SendMessageS и SendMessageL:

Код: Выделить всё

Public Declare Function SendMessageS Lib "user32.dll" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long

Public Declare Function SendMessageL Lib "user32.dll" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

[pronto]

Всем спасибо за содействие!
Наконец-то разобрался...