Как заставить окошко...

[Druid-2004]

Как заставить окошко помигать примерно также, как мигают окна в аське, когда там приходит сообщение, а окно не активно?

[tyomitch]

Код: Выделить всё

'This project needs a timer,Interval 1000

'In general section
Private Declare Function FlashWindow Lib "user32" (ByVal hwnd As Long, ByVal bInvert As Long) As Long
Const Invert = 1

Private Sub Timer1_Timer()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net

    'Flash the window
    FlashWindow Me.hwnd, Invert
End Sub


[tyomitch]

Ещё пример:

Код: Выделить всё

Const FLASHW_STOP = 0 'Stop flashing. The system restores the window to its original state.
Const FLASHW_CAPTION = &H1 'Flash the window caption.
Const FLASHW_TRAY = &H2 'Flash the taskbar button.
Const FLASHW_ALL = (FLASHW_CAPTION Or FLASHW_TRAY) 'Flash both the window caption and taskbar button. This is equivalent to setting the FLASHW_CAPTION Or FLASHW_TRAY flags.
Const FLASHW_TIMER = &H4 'Flash continuously, until the FLASHW_STOP flag is set.
Const FLASHW_TIMERNOFG = &HC 'Flash continuously until the window comes to the foreground.
Private Type FLASHWINFO
    cbSize As Long
    hwnd As Long
    dwFlags As Long
    uCount As Long
    dwTimeout As Long
End Type
Private Declare Function FlashWindowEx Lib "user32" (pfwi As FLASHWINFO) As Boolean
Private Sub Form_Load()
    'KPD-Team 1999
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Dim FlashInfo As FLASHWINFO
    'Specifies the size of the structure.
    FlashInfo.cbSize = Len(FlashInfo)
    'Specifies the flash status
    FlashInfo.dwFlags = FLASHW_ALL Or FLASHW_TIMER
    'Specifies the rate, in milliseconds, at which the window will be flashed. If dwTimeout is zero, the function uses the default cursor blink rate.
    FlashInfo.dwTimeout = 0
    'Handle to the window to be flashed. The window can be either opened or minimized.
    FlashInfo.hwnd = Me.hwnd
    'Specifies the number of times to flash the window.
    FlashInfo.uCount = 0
    FlashWindowEx FlashInfo
End Sub
Private Sub Form_Paint()
    Me.CurrentX = 0
    Me.CurrentY = 0
    Me.Print "Click me !"
End Sub


[Druid-2004]

А пояснить кто-нибудь может?

[tyomitch]

А что тут пояснять-то?
Вызываешь FlashWindow, окно мигает один раз.
Вызываешь FlashWindowEx, окно мигает сколько скажешь раз, с нужным интервалом.
FlashWindowEx доступна начиная с Win98/Win2000.