Запись результата cmd команды в файл

[tima89]

Надо чтобы результат shell'а записывался в файл. По идее в cmd это делаеться так : command > smt.txt
Я сделал кодишку на основе этого

Код: Выделить всё


dim shellquery as string
shellquery = txtquery.Text

Shell " " + shellquery + " > c:\result.txt"


Выдает ошибку, что файла не сушествует (так эта команда поидее должна же его создавать, разве не так?) Не подскажите люди добрые в чем моя ошибка? Может файл надо сначала создать?
(знаю вопрос ламерский, пару дней назад VB достал - а в новичках помоч не смогли)

[A.A.Z.]

Файл создают так:

Код: Выделить всё

Open "C:\result.txt" For Output As #1: Close #1

Однако, это проблемы не решает: ничего в файле нет.

[alibek]

Редиректом (>, <, >>) заправляет интерпретатор комманд. А при вызове из Shell аргументы передаются довольно странно, т.е. Shell пытается найти и вызвать файл с именем "prog1.exe > C:\result.txt". Естественно такого файла нет (т.к. знак > запрещен в имени файла).
Попробуй вызывать так: "cmd /c prog1.exe >c:\result.txt" - есть некоторая вероятность, что выполнится. Естественно для Win9x систем нужно вызывать не cmd, а command.

[Sur]

Генерить *.bat файл и его запускать.

[Ilya Vasilyev]

И в добавик - не забывайте про двойное >>, что позволит дописывать к указанному файлу, например, при ведении логов.

[hCORe]

А отличить command от cmd поможет функция Environ:

Код: Выделить всё

Dim ShellQuery As String
Dim Proc As String, Temp As String
ShellQuery = txtQuery.Text
Proc = Environ("COMSPEC")
If Len(Proc) = 0 Then
    Temp = Environ("WINDIR")
    If Len(Temp) = 0 Then _
    Temp = "C:\WINDOWS"
    If Right(Temp, 1) = "\" Then _
    Temp = Mid(Temp, 1, Len(Temp) - 1)
    If Len(Dir(Temp + _
    "\command.com")) = 0 Then
        Proc = Temp + "\system32\cmd.exe"
    Else
        Proc = Temp + "\command.com"
    End If
End If
Shell Proc + " /c " + ShellQuery + " > c:\result.txt", vbHide

[hCORe]

И еще: чтобы нормально прочитать файл, созданный бравой консолью Виндов (TM), надо преобразовать его в ANSI-формат:

Код: Выделить всё

Private Declare Function OemToChar Lib "user32" Alias "OemToCharA" (ByVal lpszSrc As String, _
ByVal lpszDst As String) As Long

Public Function OEM2ANSI (ByVal _
sOem As String) As String
On Error Resume Next
Dim sAnsi As String
    sAnsi = String(Len(sOem), Chr(0))
    Ret = OemToChar(sOem, sAnsi)
    OEM2ANSI = sAnsi
End Function

Public Sub GetResults()
On Error Resume Next
Dim fn As Byte, FileText As String
Dim CurrentLine As String
    fn = FreeFile
    Open "C:\result.txt" For Input As fn
    Do Until EOF(fn)
        DoEvents
        Line Input fn, CurrentLine
        If Len(CurrentLine) <> 0 Then
            FileText = FileText + CurrentLine + _
            vbCrLf
        End If
    Loop
    Close fn
    If Len(FileText) = 0 Then Exit Sub
    FileText = Mid(FileText, 1, Len(FileText) - 2)
    FileText = OEM2ANSI(FileText)
    txtResult.Text = FileText
End Sub