Как запустить dos-прогу и отследить её завершение? (+)

[Kundor]

Есть такая задача - запустить dos-прогу под w98, 2K, XP, а затем продолжить работу программы после того, как пользователь эту прогу закрыл. В MSDN есть несколько методов этого дела, только для меня ни один не срабатывает. Во-первых прога запускается только коммандой ShellExecute, всеми остальными методами (CreateProcessA, Shell) - просто прётся пустая чёрная дос консоль с работой проца на 100%). А при методе ShellExecute я не нашел методов определения - закрыта dos-прога или нет. Помогите, пжалста, если кто знает... а?

[alibek]

Код: Выделить всё

Option Explicit

Public Type STARTUPINFO
  cb As Long
  lpReserved As String
  lpDesktop As String
  lpTitle As String
  dwX As Long
  dwY As Long
  dwXSize As Long
  dwYSize As Long
  dwXCountChars As Long
  dwYCountChars As Long
  dwFillAttribute As Long
  dwFlags As Long
  wShowWindow As Integer
  cbReserved2 As Integer
  lpReserved2 As Long
  hStdInput As Long
  hStdOutput As Long
  hStdError As Long
End Type

Public Type PROCESS_INFORMATION
  hProcess As Long
  hThread As Long
  dwProcessID As Long
  dwThreadID As Long
End Type

Public Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Public Declare Function CreateProcessA Lib "kernel32" (ByVal _
   lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
   lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
   ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
   ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
   lpStartupInfo As STARTUPINFO, lpProcessInformation As _
   PROCESS_INFORMATION) As Long
Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Public Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long

Public Const NORMAL_PRIORITY_CLASS = &H20&
Public Const INFINITE = -1&
Public Const STILL_ACTIVE = &H103&

Public Function ExecCmd(CmdLine As String) As Long
Dim ret As Long
Dim proc As PROCESS_INFORMATION
Dim Start As STARTUPINFO
Start.cb = Len(Start)
ret = CreateProcessA(0&, CmdLine, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, Start, proc)
DoEvents
ret = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret)
Call CloseHandle(proc.hProcess)
ExecCmd = ret
End Function

Public Function ExecWaitCmd(CmdLine As String) As Long
Dim ret As Long
Dim proc As PROCESS_INFORMATION
Dim Start As STARTUPINFO
Start.cb = Len(Start)
ret = CreateProcessA(0&, CmdLine, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, Start, proc)
Do
  GetExitCodeProcess proc.hProcess, ret
  DoEvents
Loop While ret = STILL_ACTIVE
Call GetExitCodeProcess(proc.hProcess, ret)
Call CloseHandle(proc.hProcess)
ExecWaitCmd = ret
End Function

[Kundor]

Я так пробовал (пример похож на MSDN-овский), досовские проги (которые я тестил) запускались таким образом нормально, НО - именно та, которая мне и нужна - выводи просто чёрный экран при
ret = CreateProcessA(0&, CmdLine, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, Start, proc)

как я написал в своём вопросе - мне желательно решить задачу обнаружения завершения дос-проги при запуске её посредством shellexecute. Не понимаю почему, но только таким образом она вообще запускается...
Есть ещё идеи у кого-то?

[Sebas]

Windows Script HOst - библиотека
Будешь иметь доступ к чтению и записи в консоль