Locale_XXX api constant

[mayhem]

есть строчка кода
nSize = GetLocaleInfo(LCID, dwLCType, sReturn, Len(sReturn))

есть переменная dwLCType которая может быть
Public Const LOCALE_SCOUNTRY = &H6 ' localized name of country
Public Const LOCALE_SENGCOUNTRY = &H1002 ' English name of country

я так понял первая должна выводить "Английский (США)" а вторая "United States" допустим! Но так не происходит!

Как получить список раскладок в текущей локали а не в аглицкой?

[tyomitch]

Покажи декларацию. 90%, что проблема там.

[mayhem]

hKeyboardID получается c GetKeyboardLayout(tId)

Код: Выделить всё

Public Function getLayoutCaption(hKeyboardID)
    Dim LCID As Long
   
    If hKeyboardID > 0 Then
    '
        If hKeyboardID And &H8000& Then '32768
            LCID = &H8000& Or (hKeyboardID And &H7FFF&) '32767
        Else
            LCID = hKeyboardID And &HFFFF&
        End If
    '
        If LCID Then
            dwLCType = LOCALE_SCOUNTRY      '<-----------------
            '
            Dim sReturn As String
            Dim nSize As Long
            nSize = GetLocaleInfo(LCID, dwLCType, sReturn, Len(sReturn))
            If nSize > 0 Then
                sReturn = Space$(nSize)
                nSize = GetLocaleInfo(LCID, dwLCType, sReturn, Len(sReturn))
                getLayoutCaption = Left$(sReturn, nSize - 1)
            End If
            '
        End If
    End If
End Function


[_Мика_]

hKeyboardID получается c GetKeyboardLayout(tId)

Код: Выделить всё

Public Function getLayoutCaption(hKeyboardID)
    Dim LCID As Long
   
    If hKeyboardID > 0 Then
    '
        If hKeyboardID And &H8000& Then '32768
            LCID = &H8000& Or (hKeyboardID And &H7FFF&) '32767
        Else
            LCID = hKeyboardID And &HFFFF&
        End If
    '
        If LCID Then
            dwLCType = LOCALE_SCOUNTRY      '<-----------------
            '
            Dim sReturn As String
            Dim nSize As Long
            nSize = GetLocaleInfo(LCID, dwLCType, sReturn, Len(sReturn))
            If nSize > 0 Then
                sReturn = Space$(nSize)
                nSize = GetLocaleInfo(LCID, dwLCType, sReturn, Len(sReturn))
                getLayoutCaption = Left$(sReturn, nSize - 1)
            End If
            '
        End If
    End If
End Function


Public Function getLayoutCaption(VyVal hKeyboardID as integer)

[mayhem]

чета мне не верится что это выход! hKeyboardID - обычное число Long, по єтому пофиг как его передавать! а константі глючат по страшному!
Мне надо список язіков как в Tray висит, там на русском а у меня на аглицком вылазит!

[Andrey Fedorov]

чета мне не верится что это выход! hKeyboardID - обычное число Long, по єтому пофиг как его передавать! а константі глючат по страшному!
Мне надо список язіков как в Tray висит, там на русском а у меня на аглицком вылазит!

Приведенный ниже код выводит страну в текущей локали.
Если у тебя получится не по русски - разбирайся со своей локалью ибо она не русская...

Код: Выделить всё

Public Enum LCTYPE
    LOCALE_SLANGUAGE = &H2                  ' localized name of language
    LOCALE_SCOUNTRY = &H6                   ' localized name of country
End Enum

Public Declare Function GetLocaleInfoA Lib "kernel32" (ByVal Locale As Long, ByVal iLCTYPE As LCTYPE, ByVal sBuffer As String, iSize As Long) As Long

Public Sub Main()
    Debug.Print GetLocaleInfo(1033, LOCALE_SCOUNTRY), GetLocaleInfo(1033, LOCALE_SLANGUAGE)
End Sub

Public Function GetLocaleInfo(iLocale As Long, iType As LCTYPE) As String
    Dim i As Long, s As String * 255
    i = GetLocaleInfoA(iLocale, iType, s, Len(s))
    If i > 1 Then GetLocaleInfo = Left$(s, i - 1)
End Function


[mayhem]

вывело нормально! буду разбираться!

[Vi]

Private Declare Function GetLocaleInfoA Lib "kernel32" (ByVal Locale As Long, ByVal iLCTYPE As LCTYPE, ByVal sBuffer As String, iSize As Long) As Long

Эта функция требует в последнем параметре ByVal, т.е.
Private Declare Function GetLocaleInfoA Lib "kernel32" (ByVal Locale As Long, ByVal iLCTYPE As LCTYPE, ByVal sBuffer As String, ByVal iSize As Long) As Long

ИМХО лучше использовать W-версию этой функции, по крайней мере, у меня она выдала США вместо ??? в A-версии.

Код: Выделить всё

Private Declare Function GetLocaleInfoW Lib "kernel32" (ByVal Locale As Long, ByVal iLCTYPE As LCTYPE, _
        ByVal sBuffer As Long, ByVal iSize As Long) As Long

Public Function GetLocaleInfo(ByVal iLocale As Long, ByVal iType As LCTYPE) As String
    Dim i As Long, s As String
    s = String(255, " ")
    i = GetLocaleInfoW(iLocale, iType, StrPtr(s), Len(s))
    If i > 1 Then GetLocaleInfo = Left$(s, i - 1)
End Function